MS Word Macros

[Padawan]

Greetings, All.

I'm working on some text files I need to edit and want to write some VBA for this. But I need a little bit of help with some of the macros.

Specifically, what I'm trying to do is to search for a specific string (>> PAGE), count the occurances, then set a loop to count up to the number of occurances to number the pages.

I tried the recorder, but it didn't record what I needed. I used the find, replace all with the Find What text (^&). The message box returns replaced XX number of times. I need to capture this message box number to set my variable.

As an alternate, I can search for the >>PAGE and then overwrite the number. The problem I had was it would insert but not overwrite the number.

As a third alternative, I really don't care how I accomplish this if someone has a solution with a better technique to complete what I'm trying to do. I'm not set in stone to use the techniques I'm trying if you have a better way.

Can anyone give me a little assistance, or direct me to a website that can?

THANK YOU!!!!!

 

[ZVI]

Hi,
Try starting with follows:

Sub CountOfOccurrences()
  Dim i As Long         ' <-- count variable
  With ActiveDocument.Content.Find
    .Text = "PAGE"      ' <-- text to find
    .ClearFormatting
    .Forward = True
    .Wrap = wdFindStop  ' <-- to stop the finding loop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    While .Execute
      i = i + 1
    Wend
    MsgBox """" & .Text & """ happens " & i & " times"
  End With
End Sub


Sub ReplaceTextToOrderedNum()
  Dim i As Long
  i = 1  ' <-- "PAGE" will be replaced by: 1, 2, etc
  With ActiveDocument.Content.Find
    .Text = "PAGE"          ' <-- text to find
    .Replacement.Text = i   ' <-- replacement text
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue  ' <-- to process all occurrences
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    While .Execute(Replace:=wdReplaceOne)
      i = i + 1
    Wend
    MsgBox "Replacements = " & i - 1
  End With
End Sub

Regards,
Vladimir

 

[Padawan]

I'll try this right now. Looks like exactly what I need.

THANK YOU!

 

[Padawan]

ZVI

The counting code works fine, but I can't get the numbering to work. It is replacing the all occurances with the number "1".



Thoughts?

 

[ZVI]

Sorry, it's my misprint.
In ReplaceTextToOrderedNum() code just add below this line:
i = i + 1
that one:
.Replacement.Text = i

 

[Padawan]

That did it. I was trying to figure it out, but didn't know about adding the line.

Now I just have to tweak a little bit and I think I have it.

THANK YOU

 

[ZVI]

John,
I'm glad it has helped!
Cheers,
Vladimir