moving columns to new sheet excel VBA

[addimatty]

So I have a sheet with information in columns (approx 200) which I would like to move to new sheet. The idea is that I need column A in each new sheet following with column B, then next sheet again column A + column C and so on till the last column. Could someone help me with this?

Columns("A:B").Select
Selection.Copy
Sheets.Add After:=ActiveSheet
ActiveSheet.Paste
Sheets("Sheet1").Select
Columns("C:C").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("Sheet4").Select
Columns("C:C").Select
ActiveSheet.Paste
Sheets.Add After:=ActiveSheet
Sheets("Sheet1").Select
Range("A:B,D:D").Select
Range("D1").Activate
Application.CutCopyMode = False
Selection.Copy
Sheets("Sheet5").Select
ActiveSheet.Paste
End Sub

 

[kanadaaa]

Welcome to the forum.
Try this in a standard module:

Sub OutputColumnValuesToNewSheets()
    Dim i As Long, lc As Long, lr As Long, ws1 As Worksheet, newWs As Worksheet
    
    Set ws1 = Sheets("Sheet1")
    lc = ws1.Cells(1, Columns.Count).End(xlToLeft).Column
    lr = ws1.Cells(Rows.Count, 1).End(xlUp).Row
    
    Application.ScreenUpdating = False
    For i = 2 To lc
        Set newWs = Worksheets.Add(, Sheets(Sheets.Count))
        With newWs
            .Name = "Column " & Split(ws1.Cells(1, i).Address, "$")(1)
            ws1.Range("A1").Resize(lr).Copy .Range("A1")
            ws1.Cells(1, i).Resize(lr).Copy .Range("B1")
        End With
    Next i
    ws1.Activate
    Application.ScreenUpdating = True
    MsgBox "Exported data for " & lc & " columns", vbInformation, "Exported Data Successfully"
End Sub

 

[kanadaaa]

Also, I used the following code when I needed to delete all sheets except for Sheet1.
Maybe this will be useful for you sometimes.
Note: Don't run it unless you need to delete worksheets!

Sub DeleteSheetsExceptForSheet1()
    Dim msg As Long
    msg = MsgBox("Are you sure you want to delete all the sheets except for Sheet1?", vbYesNo, "Confirmation")
    If msg = vbYes Then
        For Each Sheet In Sheets
            Application.DisplayAlerts = False
            If Sheet.Name <> "Sheet1" Then Sheet.Delete
            Application.DisplayAlerts = True
        Next Sheet
    Else
        MsgBox "Cancelled", vbInformation
    End If
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
Another option

Sub addimatty()
   Dim Ary As Variant, Rws As Variant
   Dim i As Long
   
   Application.ScreenUpdating = False
   With Sheets("Sheet1")
      i = .Cells(1, Columns.Count).End(xlToLeft).Column
      Ary = .Range("A1", .Range("A" & Rows.Count).End(xlUp)).Resize(, i)
   End With
   Rws = Evaluate("row(1:" & UBound(Ary) & ")")
   For i = 2 To UBound(Ary, 2)
      With Sheets.Add(, Sheets(i - 1))
         .Range("A1").Resize(UBound(Ary), 2).Value = Application.Index(Ary, Rws, Array(1, i))
      End With
   Next i
End Sub