Move selected row in table to row 3

[ipbr21054]

I have a table where the Headers are in row 2
My row range is A3:I3 then down the page.
My goal is to have the user select a customers name cell in column A
The user will then use the command button code to move that customers entire row to row 3

Example
Tom Jones is currently at row 10
The user will select Tom Jones name in cell A10
Click the command button.
Tom Jones should now be at row 3.
The rows after A10 should all move up as to not have row A10 with all empty cells.

Please can you advise.
Thanks.

 

[NoSparks]

Try this

Sub testing()
    Dim oLo As ListObject
    Dim oNewRow As ListRow
    Dim moveRow As Long
    
' the table to work with
Set oLo = ThisWorkbook.ActiveSheet.ListObjects("Table1")

' is selection in first column of table
If Not Intersect(Selection, oLo.ListColumns(1).DataBodyRange) Is Nothing Then
    ' the current table listrow of selection
    moveRow = Selection.Row - Selection.ListObject.Range.Row
    
    With oLo
        ' add new row as first table row
        Set oNewRow = Selection.ListObject.ListRows.Add(1)
        ' inserting the table row moved the desired selection down a row
        
        ' make new row data equal to moveRow data
        oNewRow.Range.Value = .ListRows(moveRow + 1).Range.Value
        
        ' delete moveRow from table
        .ListRows(moveRow + 1).Delete
    End With
Else
    MsgBox "Selection is not in first column in body of table"
End If

End Sub

 

[ipbr21054]

This works fine thanks