Move Row with a specific text in a cell to different worksheet.

[yonnmd]

Hi to everyone

,
I use to check this forum a lot as a quest, but now I need your help because I am 0 in macros.
I have a task management file, where we assign task to a team consisting of 4 people, with specific deadlines. I want that when I will mark the status of a task as `done` and after this will press `Clean` cell at top, the macro will cut entire rows what are `done` and move them to worksheet Finished. I mention that we will work in this file the whole year, and in finished worksheet, rows should add below the last one.
Please find the xls on the link below.
Ty.

https://drive.google.com/open?id=1tmOVG4EkYblKZwGWKTUlT4e6emnEM7cz

 

[Meesam_ali]

Add a button in your workbook in sheet "ToDo" and when you double click the button you will reach the code window. Just paste the code below and let me know how it goes.

<code>
Private Sub CommandButton1_Click()


Call Summary


End Sub
Sub Summary()


On Error GoTo ErrorCatch


Dim ws As Worksheet


Dim newRng As Range


Dim LSearchRow As Integer
Dim i As Integer
Dim count As Integer


Set newRng = ThisWorkbook.Sheets("Finished").Range("A65335").End(xlUp).Offset(1, 0)
count = 0
ThisWorkbook.Sheets("ToDo").Select
            For LSearchRow = 3 To 250   'Can be customized as required
                If InStr(1, (Range("K" & CStr(LSearchRow)).Value), "Done") <> 0 Then
                    count = count + 1
                    Range("A" & CStr(LSearchRow), "L" & CStr(LSearchRow)).Select
                    Selection.Copy
                    newRng.Offset(count, 0).PasteSpecial xlPasteAll
                End If
            Next LSearchRow


Application.CutCopyMode = False     'clear clipboard
Sheets("Finished").Activate


ErrorCatch:
MsgBox Err.Description
End Sub
</code>

 

[Fluff]

Another option

Sub MoveDone()
   With Sheets("ToDo")
      If .AutoFilterMode Then .AutoFilterMode = False
      .Range("A2:L2").AutoFilter 11, "Done"
      With .AutoFilter.Range.Offset(1).SpecialCells(xlVisible)
         .Copy Sheets("Finished").Range("A" & Rows.Count).End(xlUp).Offset(1)
         .EntireRow.Delete
      End With
      .ShowAllData
   End With
End Sub

@Meesam_ali
When posting code please use code tags, the # icon in the reply window.

 

[yonnmd]

Ty guys!
I found that Fluff code works better, because Meesam_ali's code doesnt cut the rows from first work sheet.

 

[Fluff]

Glad we could help & thanks for the feedback