Modify macro to select specific cells and copy them to specific cells in another sheet

[caligirl626]

Have a workbook with many sheets that logs work orders per project (each sheet is a different project). The first sheet called "Project" is the main log that tracks all the work orders.
I need a macro that copies the contents of cell columns A,B,C of a project sheet where the selection has been set to column A, and copies those A,B,C contents into to the "Project" sheet columns D,E,F of the next empty row.

For example, cell A11 is selected in project sheet "6402-01" (capture1.png). When the macro is activated, it copies A11, B11, C11 and pastes them into the "Project" sheet cells D2266, E2266, F2266 because that was the next empty row of the "Project" sheet" (capture2.png).

This code does the request, but only for certain cells. Need it a bit smarter.

Sub Macro6()
'
' Macro6 Macro
'

'
    Range("A11:C11").Select
    Selection.Copy
    Sheets("Project").Select
    Range("D2266").Select
    ActiveSheet.Paste
End Sub

 

[kevin9999]

Try this on a copy of your workbook.

Option Explicit
Sub caligirl626()
    Dim ws As Worksheet
    Set ws = Worksheets("Project")
    If ActiveCell.Column = 1 Then
        ActiveCell.Resize(1, 3).Copy ws.Range("D" & ws.Cells(Rows.Count, "D").End(xlUp).Row + 1)
    End If
End Sub

 

[caligirl626]

Very nice! Can it be set to land on the "Project" sheet, the cell in column G of that line it just pasted the data in? That would be great!

 

[kevin9999]

Can it be set to land on the "Project" sheet, the cell in column G of that line it just pasted the data in

The code already copies to the Project sheet. Do you want it copied to column G of the Project sheet, and not column D as per your original post?

 

[caligirl626]

The code already copies to the Project sheet. Do you want it copied to column G of the Project sheet, and not column D as per your original post?

Oh, the code is fine as is! I was just requesting that the cursor ends up in the Column G of that line it copied to in the Project sheet. In other words, place the cursor back to the Project sheet, in the (empty) column G cell, same row as the freshly copied data.

 

[kevin9999]

Understood
Try this:

Option Explicit
Sub caligirl626()
    Dim ws As Worksheet
    Set ws = Worksheets("Project")
    If ActiveCell.Column = 1 Then
        ActiveCell.Resize(1, 3).Copy ws.Range("D" & ws.Cells(Rows.Count, "D").End(xlUp).Row + 1)
    End If
    Application.Goto ws.Range("G" & ws.Cells(Rows.Count, "D").End(xlUp).Row)
End Sub

 

[caligirl626]

Kevin shoots! He scores! Thank you!! ~Tina

 

[kevin9999]

Kevin shoots! He scores! Thank you!! ~Tina

Happy to help Tina, and thanks for the feedback

 

[caligirl626]

Hi again! Tried it this morning on my actual spreadsheet and noticed something. When the values are being copied over, it's bringing up errors because I think it's trying to copy over the formulas. Perhaps it needs a paste special command or something like that. Can the code be modified for copying only the values? thanks!

 

[kevin9999]

No worries, try this:

Option Explicit
Sub caligirl626_V2()
    Dim ws As Worksheet
    Set ws = Worksheets("Project")
    If ActiveCell.Column = 1 Then
        ActiveCell.Resize(1, 3).Copy
        ws.Range("D" & ws.Cells(Rows.Count, "D").End(xlUp).Row + 1).PasteSpecial xlPasteValues
        Application.CutCopyMode = False
    End If
    Application.Goto ws.Range("G" & ws.Cells(Rows.Count, "D").End(xlUp).Row)
End Sub