Merge Cells in one cell

[Matinmusleh]

Hello,
Need Help on my task,
I need to merge the OEM number in the attached without losing the TYPID.

 

[hagia_sofia]

Hello, please test this if it suits your cause:

=LET(
TYPID,B2:B28,
PRODUCT,C2:C28,
OEM,D2:D28,
a,UNIQUE(HSTACK(TYPID,PRODUCT)),
b,DROP(REDUCE("",UNIQUE(TYPID&PRODUCT),LAMBDA(a,b,VSTACK(a,TEXTJOIN(", ",,FILTER(OEM,TYPID&PRODUCT=b))))),1),
HSTACK(a,b))

 

[Matinmusleh]

Hello, please test this if it suits your cause:

=LET(
TYPID,B2:B28,
PRODUCT,C2:C28,
OEM,D2:D28,
a,UNIQUE(HSTACK(TYPID,PRODUCT)),
b,DROP(REDUCE("",UNIQUE(TYPID&PRODUCT),LAMBDA(a,b,VSTACK(a,TEXTJOIN(", ",,FILTER(OEM,TYPID&PRODUCT=b))))),1),
HSTACK(a,b))

Hello hagia_sofia,
Thank you for reply, but it gives Error in "FILTER(OEM,TYPID&PRODUCT=b"
Kindly check

 

[hagia_sofia]

Hello, what type of error is it (could you probably upload a screenshot)?

 

[SunnyAlv]

try

=LET(
aol,E3:E12,
bol,D3:D12,
col,F3:F12,

coun,COUNTIF(aol,UNIQUE(aol)),
un,FILTER(UNIQUE(aol),coun>1),

HSTACK(XLOOKUP(un,aol,bol),un,DROP(REDUCE("",un,LAMBDA(a,b,VSTACK(a,TEXTJOIN(", ",,FILTER(col,E3:E12=b))))),1)))

 

[RajeshKumar1313]

Hi Matinmusleh,
try this one.
=TEXTJOIN(", ",,FILTER($D$1:$D$18,($C$1:$C$18=H2)*($B$1:$B$18=G2)))

 

[Matinmusleh]

Hello, what type of error is it (could you probably upload a screenshot)?

 

[Matinmusleh]

Hi Matinmusleh,
try this one.
=TEXTJOIN(", ",,FILTER($D$1:$D$18,($C$1:$C$18=H2)*($B$1:$B$18=G2)))

Hello, Thnks ,
but the Meassge " The Function Isnt Valid

 

[hagia_sofia]

It is hard to tell what is the problem: a) do you really have Excel 365? b) What language version of Excel are you using?

 

[myall_blues]

@hagia_sofia ignore_empty parameter in TEXTJOIN is required. A Boolean is required between the two commas in front of the FILTER in OPs picture.