Merge cells in a column based on values in other columns

[Chimeara]

I have a spreadsheet with thousands of rows from bank statements. The description of some transactions have been split over 2 or 3 rows and I need to merge them into a single row. The XXXXXXXXX needs to merged into row above it. So any row with a value in the description column that is without a value in the balance column the value in the description column needs to be merged into the description cell in the row above it.
The result for the first row below should be:

02/08/2022

Inward Remittance XXXXXXXXXXXX XXXXXXXXXXXX

999,999,999.000

9,999,999.000

Current sheet

Date	Description		Debit	Credit	Balance
02/08/2022	Inward Remittance			999,999,999.000	9,999,999.000
	XXXXXXXXXXXX
	XXXXXXXXXXXX
02/08/2022	Online Acct to Acct transfer		99,999.000		999.000
03/08/2022	Salary Received		999.000		99,999.000
05/08/2022	Debit Card Purchase Card number		9999999.000		999,999,999.000
	XXXXXXXXXXXX
	XXXXXXXXXXXX

 

[mumps]

Try:

Sub CombineData()
    Application.ScreenUpdating = False
    Dim v As Variant, i As Long, arr() As Variant, lRow As Long, x As Long
    lRow = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    v = Range("A2:A" & lRow).Resize(, 6).Value
    ReDim arr(1 To WorksheetFunction.CountA(Range("A2", Range("A" & Rows.Count).End(xlUp))), 1 To 6)
    For i = LBound(v) To UBound(v)
        If v(i, 6) <> "" Then
            x = x + 1
            arr(x, 1) = v(i, 1)
            arr(x, 2) = v(i, 2)
            arr(x, 3) = v(i, 3)
            arr(x, 4) = v(i, 4)
            arr(x, 5) = v(i, 5)
            arr(x, 6) = v(i, 6)
        Else
            arr(x, 2) = arr(x, 2) & " " & v(i, 2)
        End If
    Next i
    ActiveSheet.UsedRange.Offset(1).ClearContents
    Range("A2").Resize(x, 6) = arr
    Columns.AutoFit
    Application.ScreenUpdating = True
End Sub