Make my macro ignore errors and keep going

[oliviar]

Hi Guys,
I need my macro to ignore any errors and keep going.

This is what I have. It copies data from two columns, on two seperate tables and puts them on another sheet.
Right now, if filtering produces no results to copy, it dies. I want it to just go 'oh well' if there is nothing to do, and keep going.

Sub createlist()
Sheets.Add.Name = "List"
Sheets("List").Visible = True
    Sheets("sheet1").Select
    ActiveSheet.ListObjects("Table1").Range.AutoFilter Field:=7, Criteria1:=
        "<>"
    Range("Table1[col1],table1[col4]").SpecialCells(xlCellTypeVisible).Select
    Selection.copy
    Sheets("List").Select
 Worksheets("List").Cells(Rows.Count, 1).End(xlUp).Select
ActiveCell.Offset(1, 0).Range("A1").Select
ActiveSheet.Paste
Sheets("sheet2").Select
    ActiveSheet.ListObjects("Table2").Range.AutoFilter Field:=7, Criteria1:= "<>"
    Range("Table2[col1],table2[col4]").SpecialCells(xlCellTypeVisible).Select
    Selection.copy
    Sheets("List").Select
 Worksheets("List").Cells(Rows.Count, 1).End(xlUp).Select
ActiveCell.Offset(1, 0).Range("A1").Select
ActiveSheet.Paste
End Sub

Can it be made so that it moves on if it has nothing to copy?

 

[AlphaFrog]

Sub createlist()

    Dim ws As Worksheet

    On Error Resume Next
        Set ws = Sheets("List")
    On Error GoTo 0
    If ws Is Nothing Then
        Set ws = Sheets.Add(After:=Sheets(Sheets.Count))
        ws.Name = "List"
    End If

    With Sheets("Sheet1")
        .ListObjects("Table1").Range.AutoFilter Field:=7, Criteria1:="<>"
        On Error Resume Next
        .Range("Table1[col1],table1[col4]").SpecialCells(xlCellTypeVisible).Copy _
            Destination:=ws.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        On Error GoTo 0
        .AutoFilterMode = False
    End With

    With Sheets("Sheet2")
        .ListObjects("Table2").Range.AutoFilter Field:=7, Criteria1:="<>"
        On Error Resume Next
        .Range("Table2[col1],table2[col4]").SpecialCells(xlCellTypeVisible).Copy _
            Destination:=ws.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        On Error GoTo 0
        .AutoFilterMode = False
    End With
    
End Sub

 

[Norie]

Why not check if there is nothing to copy and skip that instead of skipping the error?

You should be able to do that with the same criteria your are using for the autofilter.