Macro Works When I Press Play in Visual Basic But Doesn't With IRibbonControl

[Jambi46n2]

Hello,

When I test this code without (control As IRibbonControl) it works fine.

However when I try to run it as a button in my Add In, it doesn't do anything.
No error message or anything.

I even verified the XML in the UI Editor a number of times still no luck.

Can anyone assist?
The code below displays an email in Outlook for every worksheet with a number in cell D8.
Again, it works perfectly when I press the play button without (control As IRibbonControl).
But does nothing when I try to run it from the button.

Much thanks in advance!

Sub Email_All_Sheets(control As IRibbonControl)
'
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim sh As Worksheet
    Dim wb As Workbook
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
    Dim RngCopied As Range
    Dim NamShortList As Variant
        
    TempFilePath = Environ$("temp") & "\"


    If Val(Application.Version) < 12 Then
        'You use Excel 97-2003
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        'You use Excel 2007-2016
        FileExtStr = ".xlsm": FileFormatNum = 52
    End If


    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With


    Set OutApp = CreateObject("Outlook.Application")


    For Each sh In ThisWorkbook.Worksheets
        If sh.Range("D8").Value Like "#*" Then


            sh.Copy
            Set wb = ActiveWorkbook


            TempFileName = "Sheet " & sh.Name & " of " _
                         & ThisWorkbook.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")


            Set OutMail = OutApp.CreateItem(0)


            With wb
                .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum


    Set RngCopied = Range("A1:D17")


                On Error Resume Next
                With OutMail
                    .To = ""
                    .CC = ""
                    .BCC = ""
                    .Subject = ActiveSheet.Range("A1").Value & " - " & ActiveSheet.Range("D3").Value
                    .HTMLBody = RangetoHTML(RngCopied)
                    .Attachments.Add wb.FullName
                    'You can add other files also like this
                    '.Attachments.Add ("C:\test.txt")
                    .Display
                End With
                On Error GoTo 0


                .Close savechanges:=False
            End With
            
            Set OutMail = Nothing


            Kill TempFilePath & TempFileName & FileExtStr


        End If
    Next sh


    Set OutApp = Nothing


    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2010
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
 
    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    'Close TempWB
    TempWB.Close savechanges:=False
 
    'Delete the htm file we used in this function
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

 

[Norie]

Is the code definitely being executed?

 

[Jambi46n2]

Yes, it appears it is executing.
The mouse wheel spins, and I can see in the Visual Basic Window it cycles through the worksheets.

I was able to resolve it by creating a module in a Macro Enabled Worksheet that will be used to preform this function.
But it wont work on any active worksheet, this will suffice for the time being.

I appreciate your response

 

[Norie]

What happens if you change ThisWorkbook to ActiveWorkbook here?

    For Each sh In ThisWorkbook.Worksheets

PS ThisWorkbook refers to the workbook the code is in, so if this code is in an add-in it's probably referring to that.

 

[Jambi46n2]

That did the trick!

Excellent catch. Thank you so much!