Macro works on 3 of 4 worksheets

[cm1023]

First time posting - thanks in advance for your patience.

I have a macro to unhide/hide rows on selected sheets in a workbook based on the entry in ColB. The macro works on 3 of the 4 sheets - it does not run on the 4th 'Sponsored Funds Projection' sheet. If run while on the 4th sheet ('SFP'), it works for all 4. The 'Salary Summary' sheet is the data entry source that feeds the other sheets and I eventually want to create a button to run the macro from there, so it really needs to work from that sheet. The code I have is below (I pieced it together from various sites, including here). . Any insight is appreciated.

Sub HideUnhideRows()

Dim mySheet As Variant, sheetsToEdit As Variant
   
sheetsToEdit = Array("Salary Summary", "Personnel Detail", "All Funds Projection", "Sponsored Funds Projection")

For Each mySheet In sheetsToEdit
   
    Cells.EntireRow.Hidden = False
   
        BeginRow = 6
        EndRow = 200
        ChkCol = 2

    For RowCnt = BeginRow To EndRow
        If Cells(RowCnt, ChkCol).Value = x Then
            Cells(RowCnt, ChkCol).EntireRow.Hidden = True
            End If
    Next RowCnt
   
    Worksheets(mySheet).Activate
    MsgBox mySheet & " will be edited"
   
Next

End Sub

 

[Fluff]

Hi & welcome to MrExcel.
What is the x meant to be on this line

If Cells(RowCnt, ChkCol).Value = x Then

 

[cm1023]

x is x. The user will enter x in a cell in Col B on the Salary Summary Worksheet if they want that row unhidden (or else leave it blank). This feeds through to the corresponding rows on the other 3 worksheets. The macro is set up to first unhide all rows and then hide all those without an x in ColB.

 

[Fluff]

In that case you code is only working by pure chance, it is not looking to see if the has an x in it, it's looking to see if the cell is blank or 0.
Try

Sub HideUnhideRows()

Dim mySheet As Variant, sheetsToEdit As Variant
   
sheetsToEdit = Array("Salary Summary", "Personnel Detail", "All Funds Projection", "Sponsored Funds Projection")

For Each mySheet In sheetsToEdit
   
    Sheets(mySheet).Cells.EntireRow.Hidden = False
   
        BeginRow = 6
        EndRow = 200
        ChkCol = 2

    For RowCnt = BeginRow To EndRow
        If Sheets(mySheet).Cells(RowCnt, ChkCol).Value <> "x" Then
            Sheets(mySheet).Cells(RowCnt, ChkCol).EntireRow.Hidden = True
            End If
    Next RowCnt
   
    MsgBox mySheet & " will be edited"
   
Next

End Sub

 

[cm1023]

Thanks Fluff - your code did the trick. One lesson here is if the code 'sort of' works then it doesn't really work at all!

 

[Fluff]

You're welcome & thanks for the feedback.