Macro to prompt the person what folder to save in

[Waltert]

Can someone help me with this macro on how to have the user pick the folder

Sub Details()
'
' Details Macro
'


'
Sheets("Asset Backed ").Select
Range("A1:G28").Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:= _
"h:\AIM Shared Files\AIM\Certificate Details\loans" & Range("f12").Value & " " & Range("f4").Value & " " & Format(Date, "yyyymmdd") & ".pdf", Quality _
:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False _
, OpenAfterPublish:=True
Sheets("Sheet1").Select



End Sub

 

[Domenic]

Try...

Sub Details()

    Dim sFolder As String


    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        .ButtonName = "Select"
        .InitialFileName = Application.DefaultFilePath & "\"
        .Title = "Select Folder"
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        sFolder = .SelectedItems(1)
    End With
    
    Sheets("Asset Backed ").Range("A1:G28").ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=sFolder & "\loans" & Range("f12").Value & " " & Range("f4").Value & " " & Format(Date, "yyyymmdd") & ".pdf", _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=False, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=True


End Sub

Hope this helps!