Macro to insert a picture and size it so it fits in cell R12

[tonywatsonhelp]

Hi everyone,

I'm not very good with this so please help if you can,
I'd like a macro that can insert a picture into cell r12

no heres what i'm thinking,
when the macro is run it open the instert picture dialogue box (preferable on my pictures!)
and you choose the picture you want and click on it to insert it into excel

now I would like to move the picture so it sits where cell r12 is and sizes itself to that cell
please help if you can
thanks
Tony

 

[DanteAmor]

Try this:

Sub InsertPicture()
  Dim sPath As String
  Dim Pict As Picture
  Dim rng As Range
  
  sPath = Environ("USERPROFILE") & "\images"
  Set rng = Range("R12")
  
  With Application.FileDialog(msoFileDialogFilePicker)
    .Title = "Select pict"
    .InitialFileName = sPath
    If .Show Then
      On Error Resume Next: ActiveSheet.Pictures("pic_tem").Delete: On Error GoTo 0
      Set Pict = ActiveSheet.Pictures.Insert(.SelectedItems.Item(1))
      With Pict
        .Name = "pic_tem"
        .ShapeRange.LockAspectRatio = msoFalse
        .Top = rng.Top
        .Left = rng.Left
        .Width = rng.Width
        .Height = rng.Height
      End With
    End If
  End With
End Sub

 

[tonywatsonhelp]

Thank you
Dante Amor
this is perfefct
Tony