Macro to hide/unhide all Purple Tabs with password needs simplifying

[tonywatsonhelp]

Hi Everyone,
I have this macro that when run asks for a password then hides or unhides all purple tabs,
it works great but I only really need it to ask for a password if we are unhiding the sheets?

Can anyone edit or redo this macro so when run if the Purple tabs are visible it veryhides them but if they are hidden it asks for a passwrd then unhides them if the password is correct?
thanks

Tony

heres my code

Sub Hide_unhide_Purple_Sheets()
TABCOLOR2 = RGB(112, 48, 160) 'Purple
Dim ws As Object

Application.ScreenUpdating = False
 x = InputBox("Enter Password", "")
If x = "august" Then


For Each ws In ActiveWorkbook.Worksheets
If ws.Tab.Color = TABCOLOR2 Then
If ws.Visible = xlSheetVisible Then
ws.Visible = xlSheetVeryHidden
Else
ws.Visible = xlSheetVisible
End If
End If
Next ws

Else
For Each ws In ActiveWorkbook.Worksheets
If ws.Tab.Color = TABCOLOR2 Then
ws.Visible = xlSheetVeryHidden
End If

Next ws

End If
NewReport1.Activate
Application.ScreenUpdating = True


End Sub

 

[dmt32]

hi,
see if this update to your code does what you want

Sub Hide_unhide_Purple_Sheets()
    Dim ws              As Object
    Dim x               As Variant
    Dim TABCOLOR2       As Long
    Dim strPrompt       As String
    
    Const strPassword   As String = "august"
    
    TABCOLOR2 = RGB(112, 48, 160) 'Purple
  
    For Each ws In ActiveWorkbook.Worksheets
        If ws.Tab.Color = TABCOLOR2 Then
            If Not ws.Visible And x <> strPassword Then
                x = InputBox("Enter Password", "Enter Password")
                'cancel pressed
                If StrPtr(x) = 0 Then Exit Sub
                If x <> strPassword Then MsgBox "Invalid Password", 48, "Invalid": Exit Sub
            End If
            Application.ScreenUpdating = False
            ws.Visible = IIf(x = strPassword, xlSheetVisible, xlSheetVeryHidden)
        End If
    Next ws
    
    NewReport1.Activate
    Application.ScreenUpdating = True
End Sub

Dave

 

[tonywatsonhelp]

Hi Dave,
Thanks very much for this I'll give it a try
Tony