Macro to hide hide rows/cols below/right of current selected cell

[F_Rowan]

Hi Experts -
I am seeking VBA code that will hide all rows below and all columns right of the currently selected cell of the current active sheet. i.e.; If the current selected cell is F23, the macro should hide all rows below row 23 and all columns to the right of column F.

 

[mumps]

Maybe:

Sub HideRowsCols()
    Rows(Selection.Row & ":" & 1048576).EntireRow.Hidden = True
    Range(Cells(Selection.Column, Selection.Row), Cells(1048576, 16384)).Columns.Hidden = True
End Sub

 

[Rick Rothstein]

Give this a try...

Sub HideRowsAndColumns()
  Range(Selection.Offset(, 1), Cells(1, Columns.Count)).Columns.Hidden = True
  Range(Selection.Offset(1), Cells(Rows.Count, "A")).Rows.Hidden = True
End Sub

 

[JoeMo]

This version uses a forms control command button (Button 1 - change name to suit) located in cell A1 and initially captioned "Hide" (changes to "Unhide" to allow subsequent recovery of all columns and rows).

Sub Button1_Click()
Dim T As Range
Set T = ActiveCell
Application.ScreenUpdating = False
ActiveSheet.Shapes("Button 1").Select
Select Case Selection.Characters.Text
    Case "Hide"
        Rows(T.Row + 1 & ":" & Rows.Count).Hidden = True
        Range(Cells(1, T.Column + 1), Cells(1, Columns.Count)).EntireColumn.Hidden = True
        Selection.Characters.Text = "Unhide"
        ActiveWindow.RangeSelection.Select
    Case "Unhide"
        Cells.EntireRow.Hidden = False
        Cells.EntireColumn.Hidden = False
        Selection.Characters.Text = "Hide"
        ActiveWindow.RangeSelection.Select
End Select
Application.ScreenUpdating = True
End Sub

 

[F_Rowan]

Thank you each for your quick and clear replies. I ended up using Rick Rothstein's code for my needs.