Macro to extract sheet name after last character in subject line

[howard]

I have a macro that emails and attaches a specified sheet


I would like the code below modified so that that sheet name appears after Sale report

for eg Sales Report-BR1

 .Subject = "sales Report"

See full Code Full Code

Sub Email_SalesReport()

    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
    Dim Strinbody As String
    
    
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook


   

    'Copy the ActiveSheet to a new workbook
    Sheets("BR1").Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2013
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    'Change all cells in the worksheet to values if you want
        With Destwb.Sheets(1).UsedRange
            .Cells.Copy
            .Cells.PasteSpecial xlPasteValues
            .Cells(1).Select
        End With
        Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "" & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
           .To = Join(Application.Transpose(Range("W1:W5").Value), ";")

            .CC = ""
            .BCC = ""
            .Subject = "sales Report"
             strBody = "Hi " & Join(Application.Transpose(Range("V1:V5").Value)) & vbNewLine & vbNewLine
               strBody = strBody & "Attached Please find Sales report for your branch." & vbNewLine & vbNewLine
                    
           strBody = strBody & ""

            .Body = strBody
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Display   'Use .send to send automatically or  .Display to check email before sending
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

It would be appreciated if someone could kindly amend my code

 

[smozgur]

Hello howard,

I might be misunderstanding the question but if you need Subject of the email to include the worksheet's name then you can change the OutMail's Subject property like this:

.Subject = "Sales Report-" & Destwb.sheets(1).Name

 

[howard]

Hi Smozgur

Thanks for the reply. This is exactly what I was looking for