Macro to delete specific col Headers

[howard]

I have headers in row 1 on sheet "Data Import"


I have written code to delete a specific Col Header, but need it to delete several Col Headers for eg Physical address, Remarks, branch ID etc

 Sub DeleteSpecifcColumn()


Set MR = Range("A1:z1")
    For Each cell In MR
        If cell.Value = "Date" Then cell.EntireColumn.Delete
    Next
End Sub

It would be appreciated if someone could amend my code

 

[Marcelo Branco]

Maybe...

Sub DeleteSpecifcColumns()
    Dim MR As Range, ColToDel As Range, v As Variant

    Set MR = Sheets("Data Import").Range("A1:Z1")
    
    For Each v In Array("Date", "Physical address", "Remarks", "branch ID")
        Set ColToDel = MR.Find(v, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByColumns, _
                SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
        If Not ColToDel Is Nothing Then ColToDel.EntireColumn.Delete
    Next v
End Sub

M.

 

[howard]

Thanks for the help, Marcelo

 

[Marcelo Branco]

You are welcome. Thanks for the feedback.

M.

 

[Rick Rothstein]

For those who might find this interesting, the macro to do what the OP asked for can be reduced to two lines of code (no loops involved); however there are limitations to the method I used (see the notes below)...

[table="width: 500"]
[tr]
	[td]Sub DeleteSpecifcColumns()
  Intersect(Rows(1), Range(Replace(Mid(Join([IFERROR(REPT(":"&CHAR(64+MATCH({"Date","Physical Address","Remarks","branch ID"},A1:Z1,0)),2),"")], ","), 2), ",:", ","))).Value = "#N/A"
  Rows(1).SpecialCells(xlConstants, xlErrors).EntireColumn.Delete
End Sub[/td]
[/tr]
[/table]

Note 1
------------------------
Any columns to be deleted must lie within the column range A:Z

Note 2
------------------------
If additional headers are to be added to the list, they will go into the list highlighted in blue above with quotes around them and commas separating them. However, there is a size limitation that must be observed. The total number of characters for any additional headers plus the quote marks surrounding them plus the commas separating them cannot total more than 158 characters.

 

[howard]

Thanks for your code Rick

Always very interesting