Macro to delete entire row based on a formula result (procv)

[Ulisses_Carso]

Good afternoon,

I have small code to delete rows based on cell value, but my code doesn't work if the value is formula result.
I Make a ProcV to find a cell and i need to search and delete a row based on that ProcV but i can't figure a way to do that.
Can someone give me a light on how to solve.

Sub BuscaDeletaPlaca()

Dim rngFound As Range
Dim sht1 As Worksheet

Set sht1 = ThisWorkbook.Worksheets("Base")
With sht1.Range("A:A")
    Set rngFound = .Find(What:="desligado")
    If Not rngFound Is Nothing Then
        While Not rngFound Is Nothing
            sht1.Rows(rngFound.Row).EntireRow.Delete
            Set rngFound = .FindNext
        Wend
    End If
End With

End Sub

 

[Alex Blakenburg]

I ran a last test on my code and it didn't work when I uncommented the delete, so stay tuned,

 

[Alex Blakenburg]

I have made some changes to your code,

• The Excel Find box remembers previous settings within the same session, so I explicitly added xlValues, which should look at the result of a formula
• I have also added xlPrevious to the initial find and replaced .FindNext with .FindPrevious.
  This is because deleting rows works more efficiently if you start at the bottom, this is because Excel needs to rearrange all the rows below the deleted row.
• When I tested the .FindNext was not moving on to the next record both .FindNext & .FindPrevious needed the parameter (rngFound) added.
• I had to delete the current row "after" I did the next .FindPrevious or the code errored out.

Hope this works for you.

Sub BuscaDeletaPlaca()

    Dim rngFound As Range
    Dim sht1 As Worksheet
    Dim rowToDelete As Long    
    
    Set sht1 = ThisWorkbook.Worksheets("Base")
    With sht1.Range("A:A")
        Set rngFound = .Find(What:="desligado", LookIn:=xlValues, searchdirection:=xlPrevious)
        If Not rngFound Is Nothing Then
            While Not rngFound Is Nothing
                rowToDelete = rngFound.Row
                Set rngFound = .FindPrevious(rngFound)
                sht1.Rows(rowToDelete).EntireRow.Delete
            Wend
        End If
    End With

End Sub

 

[mohadin]

@ Ulisses_Carso
In you code Just replace with

 Set rngFound = .Find(What:="desligado", LookIn:=xlValues)

 

[Ulisses_Carso]

First, thanks for the help, both codes do what I need.

Alex, when your code delete the last row it comes into an error, "The object is required", but it delete all rows as I need
Mohadin, that "LookIn:=xlValues" resolves everything, thx dude

 

[mohadin]

You are welcome
And thank you for the feedback
Be happy & safe

 

[Alex Blakenburg]

First, thanks for the help, both codes do what I need.

Alex, when your code delete the last row it comes into an error, "The object is required", but it delete all rows as I need
Mohadin, that "LookIn:=xlValues" resolves everything, thx dude

Thanks for the feedback. Here is the updated code.
If you have a large volume of data and there are a lot of formulas on the rows, running the delete from the bottom up should be quite a bit faster.

Sub BuscaDeletaPlaca()

    Dim rngFound As Range
    Dim sht1 As Worksheet
    Dim rngToDelete As Range
        
    Set sht1 = ThisWorkbook.Worksheets("Base")
    With sht1.Range("A:A")
        Set rngFound = .Find(What:="desligado", LookIn:=xlValues, searchdirection:=xlPrevious)
        If Not rngFound Is Nothing Then
            While Not rngFound Is Nothing
                Set rngToDelete = rngFound
                Set rngFound = .FindPrevious(rngFound)
                If rngFound = rngToDelete Then Set rngFound = Nothing
                rngToDelete.EntireRow.Delete
            Wend
        End If
    End With

End Sub