Macro to count word counts in different Word docs, and enter them into Excel?

[Ripley2453]

Hi everyone,

I'm an aspiring author, and want to keep track of the word counts in my chapters.
At the moment each chapter is a different file. I would like a macro to go into each file, and tell me the word count in an excel table, for each chapter.

I'm usually pretty good at figuring macros out for myself, but I would just like a nice, simple macro that I can just copy and paste.

Anyone able to help me?

NOTE: I am using Office 2016 (365).

Cheers,
Brad.

 

[Macropod]

You do realise Word can give its own word count in a given file? Usually on the status bar or, if you prefer, in a NUMWORDS field in the document.

 

[Ripley2453]

Hi Macropod, thanks for your reply.

I am aware of that, but I have a lot of chapters saved in different files.
I want to have an excel table with all the wordcounts for each chapter, so I can keep a tally of my total novel wordcount.

Hope that makes sense,
Cheers.

 

[Macropod]

Seems overkill, but you could use an Excel macro like:

Sub GetDocumentWordCounts()
 'Note: this code requires a reference to the Word object model
Application.ScreenUpdating = False
Dim wdApp As New Word.Application
Dim wdDoc As Word.Document
Dim strFolder As String, strFile As String
Dim WkSht As Worksheet, i As Long
strFolder = GetFolder
If strFolder = "" Then Exit Sub
Set WkSht = ActiveSheet
i = 0
strFile = Dir(strFolder & "\*.docx", vbNormal)
While strFile <> ""
  i = i + 1
  Set wdDoc = wdApp.Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  WkSht.Cells(i, 1) = strFile
  WkSht.Cells(i, 2) = wdDoc.ComputeStatistics(wdStatisticWords)
  wdDoc.Close SaveChanges:=False
  strFile = Dir()
Wend
wdApp.Quit
Set wdDoc = Nothing: Set wdApp = Nothing: Set WkSht = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

Simply run the macro, select the folder then wait a moment while the workbook gets populated.

 

[Ripley2453]

No worries, I love a good macro!

Cheers mate, I'll try this when I'm home after work.
I'll let you know how it goes

 

[Ripley2453]

It's coming back with a compile error, highlighting this specific section:

'Dim wdApp As New Word.Application'

It then says 'User-defined type not defined'

Am I missing something?

 

[Macropod]

Did you read the first line of the macro:

'Note: this code requires a reference to the Word object model

 

[Ripley2453]

Did you read the first line of the macro:

I did, yes. There's 6 word files (6 chapters) so far... Can you advise how to enter them in as the reference?

 

[Macropod]

This has nothing to do with the individual Word files, but concerns the Word application. You set the reference via Tools|References in the VBE, scrolling down till you find the Microsoft Word library.

 

[Ripley2453]

This has nothing to do with the individual Word files, but concerns the Word application. You set the reference via Tools|References in the VBE, scrolling down till you find the Microsoft Word library.

Thank you, I'll give that a try.
I've never interlinked office applications via VBA before, so I wasn't aware.

Cheers!