Macro to copy Specific Cols from one sheet to another

[howard]

I have written the following code to copy data from row 1 to the last row containing data in Cols O, Q:U

However I get application defined or object defined error

 sheets(2).Range("O1:O", "Q:U" & LR).Copy Destination:=Sheets(3).Range("A1")

It would be appreciated if someone could kindly amend my code

 Sub Copy_Sales_Values()
Sheets(2).Select
Dim LR As Long

LR = Range("A" & Rows.Count).End(xlUp).Row
Sheets(3).Select
Range("A1:K" & LR).ClearContents

Sheets(2).Range("O1:O", "Q:U" & LR).Copy Destination:=Sheets(3).Range("A1")

End Sub

 

[Peter_SSs]

One simple way is just to copy 2 ranges. I have made some other changes/guesses with the code below so make sure you test in a copy of your workbook.

Sub Copy_Sales_Values()
  Dim LR As Long
  
  Sheets(3).UsedRange.ClearContents
  With Sheets(2)
    LR = .Range("A" & .Rows.Count).End(xlUp).Row
    .Range("O1:O" & LR).Copy Destination:=Sheets(3).Range("A1")
    .Range("Q1:U" & LR).Copy Destination:=Sheets(3).Range("B1")
  End With
End Sub

 

[howard]

Thanks for the help Peter

 

[Rick Rothstein]

With Peter's assumptions, this macro should also work...

[table="width: 500"]
[tr]
	[td]Sub Copy_Sales_Values()
  Dim LR As Long
  Sheets(3).UsedRange.ClearContents
  LR = Sheets(2).Cells(Rows.Count, "A").End(xlUp).Row
  Sheets(3).Range("A1:F" & LR) = Application.Index(Sheets(2).Cells, Evaluate("ROW(1:" & LR & ")"), Split("15 17 18 19 20 21"))
End Sub[/td]
[/tr]
[/table]

 

[howard]

Thanks for your input

 

[Peter_SSs]

..this macro should also work...

So long as the OP is aware that this does a very different job. eg No formulas, formatting etc copied as was the case with the OP's original code.