Macors to unhide cells

[nathans excel]

Good day,

I am new to macros but a quick learner!! I have a row of cells 11:16 that I have hidden ... I would like to add some VBA to a command button so that when it is clicked it unhides 2 rows per click ...

Click once: 11:12 unhidden
click a second time: 13:14 unhidden
3rd time 15:16 unhidden

Ive googled plenty of code to unhide the entire range which is fine ... but also not what I am looking for

Any help is appreciated, Nathan
Excel 2013

 

[Fluff]

Hi, welcome to MrExcel
Try this

Sub Unhiderws()

    Select Case True
        Case Rows(12).Hidden
            Rows("11:12").Hidden = False
        Case Rows(14).Hidden
            Rows("13:14").Hidden = False
        Case Rows(16).Hidden
            Rows("15:16").Hidden = False
    End Select

End Sub

 

[JLGWhiz]

You can attach this to a Form Controls button and each time you click the button, it will search for hidden rows and unhide the first two of any group of rows that are found each time button is clicked, so long as the rows are contiguous.

Sub t()
Dim r As Range, rw As Range
For Each r In ActiveSheet.Rows
    If r.Hidden = True Then
        If rw Is Nothing Then
            Set rw = r
        Else
            Set rw = Union(rw, r)
        End If
    End If
Next
rw.Resize(2).EntireRow.Hidden = False
End Sub

For a qucker response time, you can change the 'Rows' on the For Each line to a specific ranged like 'Range("2:20")' to reduce the seach time.

 

[nathans excel]

Fluff!!! awesome and timely response!! Much appreciated

 

[Fluff]

Glad to help & thanks for the feedback