Loop runs into subscript out of range in the last row?

[Lil2606]

Hi all,

So I have this code, works like a charm except it runs into a "run time error 9 subscript out of range" instead of just finishing.. It does the job and then in the last row it pops up the error. Any ideas why?

Sub testing2()


Dim Dict As Scripting.Dictionary
Dim DictKey As String
Dim p As Long


Set Dict = New Scripting.Dictionary


Dict.CompareMode = TextCompare


For p = 1 To Sheet4.ListObjects("EastTable").ListRows.Count


DictKey = Join(Array(Sheet4.ListObjects("EastTable").ListRows(p).Range(1, Sheet4.ListObjects("EastTable").ListColumns("First Name").Range.Column), _
                     Sheet4.ListObjects("EastTable").ListRows(p).Range(1, Sheet4.ListObjects("EastTable").ListColumns("Last Name").Range.Column)), "|")


If Not Dict.Exists(DictKey) Then
Dict.Add DictKey, Nothing


Else
Sheet4.ListObjects("EastTable").ListRows(p).Delete


End If


Next


End Sub

Could anyone help please?

Question posted on ExcelForum as well link: https://www.excelforum.com/excel-pr...out-of-range-in-the-last-row.html#post5070127

 

[DanteAmor]

The problem is that when you delete a row the counter p no longer exists for the last row.
This could be a solution:

Sub testing2()
    Dim Dict As Scripting.Dictionary
    Dim DictKey As String
    Dim p As Long, u As Long
    
    Set Dict = New Scripting.Dictionary
    Dict.CompareMode = TextCompare
    For p = 1 To Sheet4.ListObjects("EastTable").ListRows.Count
        If p > Sheet4.ListObjects("EastTable").ListRows.Count Then Exit For
        DictKey = Join(Array(Sheet4.ListObjects("EastTable").ListRows(p).Range(1, Sheet4.ListObjects("EastTable").ListColumns("First Name").Range.Column), _
                    Sheet4.ListObjects("EastTable").ListRows(p).Range(1, Sheet4.ListObjects("EastTable").ListColumns("Last Name").Range.Column)), "|")
        
        If Not Dict.Exists(DictKey) Then
            Dict.Add DictKey, Nothing
        Else
            Sheet4.ListObjects("EastTable").ListRows(p).Delete
            p = p - 1
        End If
    Next
End Sub

 

[Lil2606]

Thank you! I actually just came back to say that if I make it count backwards it works

 

[DanteAmor]

Thank you! I actually just came back to say that if I make it count backwards it works

That was my original idea but I did not know if you wanted to erase the first or the last duplicates