Looking up Dictionary (Dict) returns bank result?

[MrGadget2000]

I'm trying to use a dictionary (new to these) and it appears to record the data correctly, however when I try to get the item for a particular key I get a blank result.

To show, I have the following in A1:C3;

Apples	Red	5​
Bananas	Yellow	2​
Oranges	Orange	3​

And the code;

Sub testdict()
    Dim lastrow As Long
    Dim cnt As Long, fruit As String
    Dim dict As New Scripting.Dictionary

    lastrow = Sheet1.Range("A" & Rows.Count).End(xlUp).Row
    
    'Set dictionary Items
    For n = 1 To lastrow
        dict.Add Key:=Range("A" & n), Item:=Range("C" & n)
    Next n
    
    'Print Debug Items to immediate - this works;
        'Apples 5
        'Bananas 2
        'Oranges 3
    For i = 0 To dict.Count - 1
        Debug.Print dict.Keys(i), ; dict.Items(i)
    Next i
    
    fruit = "Bananas"
    cnt = dict(Bananas)
    
    Debug.Print "Dict="; dict("Bananas")         ' is blank result
    Debug.Print "Dict 'fruit'="; dict(fruit)     ' is blank result
    Debug.Print "Dict CStr'fruit'="; dict(CStr(fruit)) ' is blank result
    Debug.Print "Dict="; CStr(dict("Bananas"))   ' is blank result
    Debug.Print "cnt=", cnt                      ' is 0
    Debug.Print "cnt (CStr)=", CStr(cnt)         ' is 0

End Sub

I was trying the same code with the addition of the CStr as another post indicated this as a potential solution, however it makes no difference to the outcome.
No matter what I try, I don't seem to be able to get the qty of a fruit.

I'm sure it's a simple resolution but by use of Dictionaries is just starting.

Cheers

 

[bebo021999]

"If" should be used to check if dict key is existed, also using .value:

For n = 1 To lastrow
        If Not dict.exists(Range("A" & n).Value) Then
            dict.Add Range("A" & n).Value, Range("C" & n).Value
        End If
    Next

 

[MrGadget2000]

"If" should be used to check if dict key is existed, also using .value:

For n = 1 To lastrow
        If Not dict.exists(Range("A" & n).Value) Then
            dict.Add Range("A" & n).Value, Range("C" & n).Value
        End If
    Next

Ahh - the .value works! Knew it would be obvious to someone who knows - thank you!

I did note that I should check if it exists, but wondered if that was really necessary? In short, I will only add to the dictionary at the start, then will make no other additions or changes to it from there, only reading from it as required. I guess it's just good code practice at least unless there is any other obvious reasoning.

Again - thanks - went through a dozen or so mages and missed this.

 

[BSALV]

Excel VBA Dictionary - A Complete Guide - Excel Macro Mastery

This post contains everything you need to know about using the VBA Dictionary. There are tons of code examples including a real world application.

excelmacromastery.com

it's indeed a good practice to check if the key already exists, otherwis you run into errors.

Remark : a dictionary is case sensitive but you can use dict.CompareMode = vbTextCompare

 

[bebo021999]

By change, your items are not dupplicate, then dictionary works!
If you want to collect them all (regardless dupplicate), using a collection, or an array.
If you want to store unique items, use dictionary, with "not dict.exists" to check if it dupplicate.