Looking for a stop command for my formula

[Robert Wyatt]

I was wondering if that is some way to have my formula stop once it reaches the date set for in each column until a new year is placed in column C2?

Days Remaining in 2023 Holiday List.xlsx
	A	B	C	D
1	Days remaining in 2023 Holiday List
2		Year	2023
3
4	Event	When	This Year	Days Left
5	Martin Luther King Jr. Day	The 3rd Monday In January	1/16/2023	-93 days
6	President's Day	The 3rd Monday in February	2/20/2023	-58 days
7	Memorial Day	The last Monday in May	5/29/2023	40 days
8	Independence Day	July 4	7/4/2023	76 days
9	Labor Day	The 1st Monday In Sepetmeber	9/4/2023	138 days
10	Columbus Day	The 2nd Monday in October	10/9/2023	173 days
11	Holloween	Novermber 31	10/31/2023	195 days
12	Veteran's Day	Novermber 11	11/11/2023	206 days
13	Thanksgiving Day	The 4th Thursday in November	11/23/2023	218 days
14	My Birthday	December 7	12/7/2023	232 days
15	Christmas Day	December 25	12/25/2023	250 days
16	New Year's	January 1	1/1/2023	-108 days
Sheet1

Cell Formulas
Range	Formula
C5	C5	=DATE(C2,1,1)+14+CHOOSE(WEEKDAY(DATE(C2,1,1)),1,0,6,5,4,3,2)
D5:D16	D5	=IF(C5="","",C5-TODAY()& " days")
C6	C6	=DATE(C2,2,1)+14+CHOOSE(WEEKDAY(DATE(C2,2,1)),1,0,6,5,4,3,2)
C7	C7	=DATE(C2,6,1)-WEEKDAY(DATE(C2,6,6))
C8	C8	=DATE(C2,7,4)
C9	C9	=DATE(C2,9,1)+CHOOSE(WEEKDAY(DATE(C2,9,1)),1,0,6,5,4,3,2)
C10	C10	=DATE(C2,10,1)+7+CHOOSE(WEEKDAY(DATE(C2,10,1)),1,0,6,5,4,3,2)
C11	C11	=DATE(C2,10,31)
C12	C12	=DATE(C2,11,11)
C13	C13	=DATE(C2,11,1)+21+CHOOSE(WEEKDAY(DATE(C2,11,1)),4,3,2,1,0,6,5)
C14	C14	=DATE(C2,12,7)
C15	C15	=DATE(C2,12,25)
C16	C16	=DATE(C2,1,1)

 

[Joe4]

You mean so no negative values show in column D?
You could revise the formula in column D to this:

=IF(C5="","",MAX(C5-TODAY(),0) & " days")

 

[Robert Wyatt]

Yes and it works great thanks, I wouldn't know what to do if I couldn't find help from people with good minds. you need a rise, my good man. lol. Thanks again for the help.

 

[Joe4]

You are welcome.
Glad I was able to help!