Looking for a sorting formula

[MiniFav]

I have the following table

Book1
	A	B	C	D	E	F
2	Interval	FH	FC	DY	WY	YR
3	32FH 50FC 10DY 15WY 20YR	32	50	10	15	20
Sheet1

Cell A3 has numerous values which i would like to extract and put into the correct column. I am looking for a formula (no macros or VBA) to input into each column (B-F) which will look at column A and extract the relevant value.
Cell A3 wont always have the same information available, for example might no show DY or WY every time so in this case columns D and E would be left blank.

Does anyone have any expertise in this and able to help?

 

[Peter_SSs]

Here is one way

22 01 06.xlsm
	A	B	C	D	E	F
2	Interval	FH	FC	DY	WY	YR
3	32FH 50FC 10DY 15WY 20YR	32	50	10	15	20
4	24.5YR 5698FC		5698			24.5
Extract Values

Cell Formulas
Range	Formula
B3:F4	B3	=LET(f,FILTERXML("<p><c>"&SUBSTITUTE($A3,CHAR(10),"</c><c>")&"</c></p>","//c"),SUBSTITUTE(FILTER(f,RIGHT(f,LEN(B$2))=B$2,""),B$2,""))

 

[Peter_SSs]

Another (shorter) option that would also return the results as numbers rather than text

22 01 06.xlsm
	A	B	C	D	E	F
2	Interval	FH	FC	DY	WY	YR
3	32FH 50FC 10DY 15WY 20YR	32	50	10	15	20
4	24.5YR 5698FC		5698			24.5
Extract Values2

Cell Formulas
Range	Formula
B3:F4	B3	=LET(s,SUBSTITUTE(CHAR(10)&$A3,CHAR(10),REPT(" ",20)),IFERROR(MID(s,FIND(B$2,s)-20,20)+0,""))

 

[MiniFav]

Here is one way

22 01 06.xlsm
	A	B	C	D	E	F
2	Interval	FH	FC	DY	WY	YR
3	32FH 50FC 10DY 15WY 20YR	32	50	10	15	20
4	24.5YR 5698FC		5698			24.5
Extract Values

Cell Formulas
Range	Formula
B3:F4	B3	=LET(f,FILTERXML("<p><c>"&SUBSTITUTE($A3,CHAR(10),"</c><c>")&"</c></p>","//c"),SUBSTITUTE(FILTER(f,RIGHT(f,LEN(B$2))=B$2,""),B$2,""))

Thank you! this is incredible.

 

[Peter_SSs]

You're welcome. Thanks for the follow-up.