Looking for a more efficient method for point scoring

[Marvo]

Hi. In the example, I have two teams (Lions & Cheetahs) who are playing each other. The winner is the team with the lowest score from either pair. I've sorted a way to do it but it seems a bit convoluted and I'm sure one of you could show me an simpler way. Many thanks.

Book1
	A	B	C	D
1		Game 1	Game 2	Game 3
2	Lions A	5	4	4
3	Lions B	4	3	5
4	Cheetahs A	3	3	6
5	Cheetahs B	6	4	7
6
7	Lions Min	4	3	4
8	Cheetahs Min	3	3	6
9	lions	0	0	1
10	Cheetahs	1	1	1
Sheet1

Cell Formulas
Range	Formula
B7:D7	B7	=MIN(B2:B3)
B8:D8	B8	=MIN(B4:B5)
B9	B9	=IF(B7<B8,1,0)
C9:D9	C9	=IF(C7<C8,1,0)+B9
B10	B10	=IF(B8<B7,1,0)
C10:D10	C10	=IF(C8<C7,1,0)+B10

 

[Phuoc]

Try this:

Book1
	A	B	C	D
1		Game 1	Game 2	Game 3
2	Lions A	5	4	4
3	Lions B	4	3	5
4	Cheetahs A	3	3	6
5	Cheetahs B	6	4	7
6
7	lions	0	0	1
8	Cheetahs	1	1	1
Sheet1

Cell Formulas
Range	Formula
B7	B7	=IF(MIN(B2:B3)<MIN(B4:B5),1,0)
C7:D7	C7	=IF(MIN(C2:C3)<MIN(C4:C5),1,0)+$B7
B8	B8	=IF(MIN(B2:B3)>MIN(B4:B5),1,0)
C8:D8	C8	=IF(MIN(C2:C3)>MIN(C4:C5),1,0)+B8

 

[Kaper]

I'd go a bit further. Just 2 formulas:
in B7 and copy to right (Lions):

=SUM(A7,MIN(B2:B3)<MIN(B4:B5))

and in B8 and copy right (Cheetahs):

=SUM(A8,MIN(B4:B5)<MIN(B2:B3))

The key element is of course comparision of minimas: MIN(B2:B3)<MIN(B4:B5 but then, when it is added to something, excel converts boolean result of comparision (TRUE/FALSE) to 1/0.
So IF function is not needed.
I used SUM function, not just + sign, because SUM treats text in column A as 0. Of course when formula is copied right SUM takes previous result and adds to current one.

 

[Marvo]

That's fabulous guys, thank you so much.

 

[Kaper]

Glad we could help