Locking of cells with protected sheet not working

[Eurekaonide]

Hi All

I think there is probably something very small and simple I am missing here as it did seem to work but now is not.

I have a form with checkboxes on it, when a checkbox is selected it will Lock the cells for editing in the corresponding Column, hide the column off and then when the OK button is pressed it protects the sheet (currently without a password).

For some reason it is now not locking the cells.

This is an example of the code for the checkboxes
Private Sub CheckBox1_Click()
Sheets("Data").Select
 ActiveSheet.Unprotect
If Me.CheckBox1.Value = True Then
    Sheets("Data").Columns("Q:Q").Hidden = True
    Selection.Locked = True
ElseIf Me.CheckBox1.Value = False Then
    Sheets("Data").Columns("Q:Q").Hidden = False
    Selection.Locked = False
End If

End Sub

and this is the code for the OK button

Private Sub CommandButton1_Click() 'OK
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _
        , AllowFormattingCells:=True, AllowFormattingRows:=True, _
        AllowInsertingRows:=True, AllowFiltering:=True, AllowFormattingColumns:=True
       
Unload Me

End Sub

Can you see what I am doing wrong please?

 

[Artik]

Which is selected before this line is executed:

Selection.Locked = True

Artik

 

[Eurekaonide]

Which is selected before this line is executed:

Selection.Locked = True

Artik

The Checkbox is either selected or not and then the OK Button is selected.

I wondered if I need to Lock then Hide?

 

[Eurekaonide]

The Checkbox is either selected or not and then the OK Button is selected.

I wondered if I need to Lock then Hide?

Ive changed my checkbox code to the below and I think it has resolved it.

Private Sub CheckBox1_Click()
Sheets("Data").Select
 ActiveSheet.Unprotect
If Me.CheckBox1.Value = True Then
    Sheets("Data").Columns("Q:Q").Locked = True
    Sheets("Data").Columns("Q:Q").Hidden = True
ElseIf Me.CheckBox1.Value = False Then
    Sheets("Data").Columns("Q:Q").Locked = False
    Sheets("Data").Columns("Q:Q").Hidden = False
End If

End Sub

 

[Artik]

It can be written in shorter form:

Private Sub CheckBox1_Click()
    With Worksheets("Data")
        .Unprotect
        With .Columns("Q")
            .Locked = Me.CheckBox1.Value
            .Hidden = Me.CheckBox1.Value
        End With
        '.Select 'If necessary
    End With
End Sub

Artik

 

[Eurekaonide]

It can be written in shorter form:

Private Sub CheckBox1_Click()
    With Worksheets("Data")
        .Unprotect
        With .Columns("Q")
            .Locked = Me.CheckBox1.Value
            .Hidden = Me.CheckBox1.Value
        End With
        '.Select 'If necessary
    End With
End Sub

Artik

Thank you