loading a picture from spreadsheet into userform

[hearthhrob4gals]

Hi,

I have few images in a sheet called 'Images'. Once the userform initializes, i want the 1st image (Picture 1) from the 'Images' sheet to be uploaded in the userform. I have written the below code. However getting error. Any help would eb appreciated

Worksheets("Images").Select
UserForm1.Picture = LoadPicture(ActiveSheet.Shapes("Picture 1"))

.

 

[MickG]

You can't do that directly you need to some code to paste the picture into a Chart object, save to file then recall that file.
Do you only need to show one picture or do you need to swap the pictures.???

 

[hearthhrob4gals]

hi,

i have 3 pictures....initially on userform_initialize one needs to be uploaded.... then upon clicking options in a listbox, the userform picture should change..is that possible?

 

[hearthhrob4gals]

hi,

i have 3 pictures....initially on userform_initialize one needs to be uploaded.... then upon clicking options in a listbox, the userform picture should change..is that possible?

 

[MickG]

Your Userform should have an "Image Control" (Image1) and a "ListBox" (ListBox1).
The pictures are assumed to be on sheet2 (Change Sheet name in code as required,(2 places, sub "Pict", and "Initialize")
When you run the code the first image name in your listbox will be loaded.
After that it will change based on the Listbox selection.

Place the code below in the Userfrom Module:-

Option Explicit
Private Sub ListBox1_Click()
Call Pict(ListBox1.ListIndex)
End Sub


Private Sub UserForm_Initialize()
Dim Pic As Object
 For Each Pic In Sheets("Sheet2").Pictures
    If TypeName(Pic) = "Picture" Then
        ListBox1.AddItem Pic.Name
    End If
    Next Pic
ListBox1.ListIndex = 0
Call Pict(0)
End Sub


Sub Pict(n)
Dim Ans As String
Dim rng As Excel.Range
Dim cht As Excel.ChartObject
Dim Pth As String
Dim Pic As Object
With ListBox1
  Set Pic = Sheets("sheet2").Shapes(.List(n))
  Pic.Copy 'Picture xlScreen, xlBitmap
Dim Strpath As String
Strpath = ThisWorkbook.Path & "\Temp.jpg"
   Set cht = ActiveSheet.ChartObjects.Add(100, 0, Pic.Width, Pic.Height)
    cht.Chart.Paste
      cht.Chart.Export Strpath
        cht.Delete
Set cht = Nothing
Me.Image1.Picture = LoadPicture(Strpath)
End With
End Sub

 

[hearthhrob4gals]

worked like a charm!!! Thanks a ton : )

 

[MickG]

You're welcome