listbox.rowsource not available on Excel for Mac

[andrevni22]

Hello,
I have tried everything to find a solution for that. My code is working perfectly on Windows.
Is there any equivalent function for the RowSource to use in Excel for Mac?
I do not want to use listbox.add, because I want for multiple columns. This is my code that works perfectly on Windows:

.lbPlanListPE.ColumnCount = 6
.lbPlanListPE.ColumnWidths = "0;119;105;0;102;90"
.lbPlanListPE.RowSource = "PlanosPegarEmprestado"

Many thanks in advance.

 

[6StringJazzer]

You can use ListBox.Add for the first column, then populate the subsequent columns.

   Dim R As Long, C As Long
   
   With Me.lbPlanListPE
   
      .Clear

      For R = 1 To Range("PlanosPegarEmprestado").Rows.Count
      
         .AddItem Range("PlanosPegarEmprestado").Cells(R, 1)
         
         For C = 2 To Range("PlanosPegarEmprestado").Columns.Count
            .List(.ListCount - 1, C - 1) = Range("PlanosPegarEmprestado").Cells(R, C)
         Next C
         
      Next R
      
   End With

 

[andrevni22]

You can use ListBox.Add for the first column, then populate the subsequent columns.

   Dim R As Long, C As Long
  
   With Me.lbPlanListPE
  
      .Clear

      For R = 1 To Range("PlanosPegarEmprestado").Rows.Count
     
         .AddItem Range("PlanosPegarEmprestado").Cells(R, 1)
        
         For C = 2 To Range("PlanosPegarEmprestado").Columns.Count
            .List(.ListCount - 1, C - 1) = Range("PlanosPegarEmprestado").Cells(R, C)
         Next C
        
      Next R
     
   End With

Thank you very much! It worked!!!!

 

[6StringJazzer]

Here is a much simpler way

   With Me.lbPlanListPE
   
      .Clear

      .List = Range("PlanosPegarEmprestado").Value
         
   End With