Listbox displaying more decimal places than the worksheet it is referencing

[ijhoeq]

Hello,
I am trying to create a listbox that displays a table from a worksheet ('Liquid Charge Control Sheet') using the code below. The worksheet displays only one decimal place (i.e. 100.5) but when I reference that cell in the listbox it displays "100.50000000000000". Can someone show me how to display only one decimal place in the listbox? Thanks!

Private Sub Table_CommandButton_Click()


    Dim ws As Worksheet
    Dim rng As Range
    Dim MyArray
    
    Set ws = Sheets("Liquid Charge Control Sheet")
    
    Set rng = ws.Range("F31:H" & ws.Range("F" & ws.Rows.Count).End(xlUp).Row)
    
    With Me.ListBox1
        .Clear
        .ColumnHeads = False
        .ColumnCount = rng.Columns.Count
        
        MyArray = rng
        .List = MyArray
        .ColumnWidths = "50;50"
        .TopIndex = 0
    End With


End Sub

 

[Domenic]

As you see, the underlying values are being picked up, not the displayed values. Simply round those numbers before assigning them to your listbox...

Private Sub CommandButton1_Click()

    Dim ws As Worksheet
    Dim MyArray As Variant
    Dim i As Long
    
    Set ws = Sheets("Liquid Charge Control Sheet")
    
    MyArray = ws.Range("F31:H" & ws.Range("F" & ws.Rows.Count).End(xlUp).Row).Value
    
    For i = LBound(MyArray, 1) To UBound(MyArray, 1)
        MyArray(i, 1) = Round(MyArray(i, 1), 1)
    Next i
    
    With Me.ListBox1
        .Clear
        .ColumnHeads = False
        .ColumnCount = UBound(MyArray, 2)
        
        .List = MyArray
        .ColumnWidths = "50;50"
        .TopIndex = 0
    End With

End Sub

By the way, you can replace...

 MyArray = ws.Range("F31:H" & ws.Range("F" & ws.Rows.Count).End(xlUp).Row).Value

with

    With ws
        MyArray = .Range("F31:H" & .Cells(.Rows.Count, "F").End(xlUp).Row).Value
    End With

Hope this helps!

 

[ijhoeq]

Works great! Thanks a lot!

 

[Domenic]

You're very welcome! Glad I could help!

Cheers!