List properties of images in workbook

[mwperkins]

Hi,
Does anyone have some code that can loop through each sheet in the activeworkbook and list all shapes/images and their dimensions / properties?

I am most interested in the resolution of the images, but it would be useful to know other info too.


Can anyone help?

thanks,
Mark

 

[Yongle]

Here is a starting point for you
Put this code in a new module and run LoopShapes

Option Explicit
Private wb As Workbook, ws As Worksheet, sh As Long, sName As String, cel As Range
Private Shp As Shape, N As String, W As Double, H As Double, TLC As String, BRC As String, T As Integer

Sub LoopShapes()
    Call Environment
    
    For sh = 1 To wb.Worksheets.Count
        For Each Shp In wb.Worksheets(sh).Shapes
            sName = wb.Worksheets(sh).Name
            Call GetCommonDetails
            cel.End(xlUp).Offset(1).Resize(, 7) = Array(sName, N, H, W, TLC, BRC, T)
        Next Shp
    Next sh
End Sub

Private Sub Environment()
    Set wb = ThisWorkbook
    Set ws = wb.Worksheets.Add
    Set cel = ws.Cells(Rows.Count, "A")
    With ws.Range("A1").Resize(, 7)
        .Value = Split("Sheet Name Height Width TopLeft BottomRight ShapeType")
        .Font.Bold = True
        .ColumnWidth = 20
    End With
End Sub

Private Sub GetCommonDetails()
    With Shp
        N = .Name
        H = .Height
        W = .Width
        TLC = .TopLeftCell.Address(0, 0)
        BRC = .BottomRightCell.Address(0, 0)
        T = .Type
     End With
End Sub

 

[mwperkins]

Many thanks for the reply. In the GetCommonDetails, is it possible to include resolution?

 

[Yongle]

Here is a link that may help
- image resolution details are available at file level

https://www.devhut.net/2018/10/23/vba-get-image-properties-dimensions-etc/