List of distinct names

[Antonio B]

Hi,
I have names in colum A and surnames in column B and want list of distinct names and surnames in collumns C and D.
My excel is 2016 and I need solution with formula (INDEX, MATCH, COUNTIF(S) and similar).
My data are in columns A and B, result in columns C and D.

A	B	C	D
First Name	Last Name	First Name	Last Name
Ronnie	Anderson	Ronnie	Anderson
Robert	Jones	Robert	Jones
Sally	Brooke	Sally	Brooke
David	White	David	White
Ronnie	Anderson	Mattias	Waldau
Mattias	Waldau	Robert	Brooke
Robert	Brooke	Sally	Anderson
David	White
Robert	Jones
Robert	Jones
Sally	Anderson

Thank you.

 

[JEC]

Power Query would be easier

 

[hagia_sofia]

If you do not insist on the output as depicted above then you could e.g. use:

=IF(COUNTIFS(A$2:A2,A2,B$2:B2,B2)=1,A2,"")

=IF(COUNTIFS(A$2:A2,A2,B$2:B2,B2)=1,B2,"")

 

[Peter_SSs]

Welcome to the MrExcel board!

Try this formula in C2, copied across and down

24 10 27.xlsm
	A	B	C	D
1	First Name	Last Name	First Name	Last Name
2	Ronnie	Anderson	Ronnie	Anderson
3	Robert	Jones	Robert	Jones
4	Sally	Brooke	Sally	Brooke
5	David	White	David	White
6	Ronnie	Anderson	Mattias	Waldau
7	Mattias	Waldau	Robert	Brooke
8	Robert	Brooke	Sally	Anderson
9	David	White
10	Robert	Jones
11	Robert	Jones
12	Sally	Anderson
Unique names

Cell Formulas
Range	Formula
C2:D12	C2	=IFERROR(INDEX(A:A,AGGREGATE(15,6,ROW(A$2:A$12)/((MATCH($A$2:$A$12&"|"&$B$2:$B$12,$A$2:$A$12&"|"&$B$2:$B$12,0)=(ROW(A$2:A$12)-ROW(A$2)+1))*(ISERROR(MATCH($A$2:$A$12&"|"&$B$2:$B$12,$C$1:$C1&"|"&$D$1:$D1,0)))),1)),"")