List of all working days between two dates

[StefaniaPana]

I found the below VBA that returns a list of all the days between working days that works perfectly.
But I need it to return only the working days, is there a line or smth that I need to add to do so?

Sub WriteDates()

Dim rng As Range
Dim StartRng As Range
Dim EndRng As Range
Dim OutRng As Range
Dim StartValue As Variant
Dim EndValue As Variant
xTitleId = "KutoolsforExcel"
Set StartRng = Application.Selection
Set StartRng = Application.InputBox("Start Range (single cell):", xTitleId, StartRng.Address, Type:=8)
Set EndRng = Application.InputBox("End Range (single cell):", xTitleId, Type:=8)
Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
Set OutRng = OutRng.Range("A1")
StartValue = StartRng.Range("A1").Value
EndValue = EndRng.Range("A1").Value
If EndValue - StartValue <= 0 Then
Exit Sub
End If
ColIndex = 0
For i = StartValue To EndValue
OutRng.Offset(ColIndex, 0) = i
ColIndex = ColIndex + 1
Next
End Sub

 

[6StringJazzer]

Try this code. I also declared your undeclared variables (use Option Explicit). (Also please note how helpful code tags are.) Note that this does not take holidays into account. If you have a list of holidays then you can modify the If statement accordingly.

Sub WriteDates()

   Dim rng As Range
   Dim StartRng As Range
   Dim EndRng As Range
   Dim OutRng As Range
   Dim StartValue As Variant
   Dim EndValue As Variant
   Dim xTitleId As String
   Dim ColIndex As Long
   Dim i As Long
  
   xTitleId = "KutoolsforExcel"
   Set StartRng = Application.Selection
   Set StartRng = Application.InputBox("Start Range (single cell):", xTitleId, StartRng.Address, Type:=8)
   Set EndRng = Application.InputBox("End Range (single cell):", xTitleId, Type:=8)
   Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
   Set OutRng = OutRng.Range("A1")
   StartValue = StartRng.Range("A1").Value
   EndValue = EndRng.Range("A1").Value
  
   If EndValue - StartValue <= 0 Then
      Exit Sub
   End If
  
   ColIndex = 0
  
   For i = StartValue To EndValue
      If Weekday(i, vbSaturday) > 2 Then
         OutRng.Offset(ColIndex, 0) = i
         ColIndex = ColIndex + 1
      End If
   Next
  
End Sub