List a range of numbers excluding those in another column

[Red over White]

I’m looking to develop a doughnut graph, but first need to get the figures in the right order.

The main area I’m struggling with is Column G. What I’m looking for is a consecutive list of numbers that omits those numbers in Column F (there will be no more than five such numbers in this column).

Should the numbers change in Column F I can alter what is in Columns H to K by macro, but if there is a formula that would be an added bonus!

Thanks

Doughnut 2.xlsx
	A	B	C	D	E	F	G	H	I	J
2
3	Example 1	0.3%		1	21.182%	4	3	Example 2	21.2%
4	Example 2	21.2%		2	19.345%	23	5	Example 21	19.3%
5	Example 3	0.3%		3	17.939%	16	6	Example 14	17.9%
6	Example 4	2.3%		4			7	Example 1		0.3%
7	Example 5	1.1%		5			8	Example 3		0.3%
8	Example 6	6.6%		6			9	Example 4		2.3%
9	Example 7	1.5%		7			10	Example 5		1.1%
10	Example 8	0.6%		8			11	Example 6		6.6%
11	Example 9	0.5%		9			12	Example 7		1.5%
12	Example 10	0.6%		10			13	Example 8		0.6%
13	Example 11	6.9%		11			14	Example 9		0.5%
14	Example 12	0.7%		12			15	Example 10		0.6%
15	Example 13	0.5%		13			17	Example 11		6.9%
16	Example 14	17.9%		14			18	Example 12		0.7%
17	Example 15	0.3%		15			19	Example 13		0.5%
18	Example 16	3.2%		16			20	Example 15		0.3%
19	Example 17	0.3%		17			21	Example 16		3.2%
20	Example 18	1.2%		18			22	Example 17		0.3%
21	Example 19	2.6%		19			24	Example 18		1.2%
22	Example 20	0.8%		20			25	Example 19		2.6%
23	Example 21	19.3%		21			26	Example 20		0.8%
24	Example 22	0.2%		22			27	Example 22		0.2%
25	Example 23	0.9%		23			28	Example 23		0.9%
26	Example 24	3.4%		24			29	Example 24		3.4%
27	Example 25	0.3%		25			30	Example 25		0.3%
28	Example 26	4.4%		26			31	Example 26		4.4%
29	Example 27	0.7%		27			32	Example 27		0.7%
30	Example 28	0.8%		28			33	Example 28		0.8%
31				29
32				30
33				31
Exclusion

Cell Formulas
Range	Formula
E3:E8	E3	=IF(LARGE($B$3:$B$30,D3)>E$1,LARGE($B$3:$B$30,D3),"")
I3:I23	I3	=IFERROR(IF(INDIRECT("B"&F3)>E$1,INDIRECT("B"&F3),""),"")
H3:H5	H3	=IF(F3="","",INDIRECT("A"&F3))
H6:H30	H6	=INDIRECT("A"&SMALL($G$3:$G$27,D3))
J6:J30	J6	=IFERROR(IF(INDIRECT("B"&G3)<E$1,INDIRECT("B"&G3),""),"")
F3:F32	F3	=IFERROR(SUM(MATCH(E3,$B$3:$B$30,0)+2),"")

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B3	Cell Value	<=0.15%	text	NO

 

[Fluff]

Why does col G start at 3 rather than 1?

 

[Red over White]

So that it matches the row number. What I looking for is a list of row numbers that exclude the row numbers in Column F. My premise is that I can use the first number in the top formula in columns H and J and then drag the formulas down to the bottom to list all the values less than 15%. For example using 3 will bring across Example 1 (A3) and 0.3% (B3).
Regards

 

[Fluff]

Ok, how about

=WORKDAY.INTL(2,SEQUENCE(ROWS(B3:B30)),"0000000",FILTER(F3:F30,F3:F30<>""))

 

[Red over White]

I have put your formula in G3 but am getting SPILL! in return. I am a bit confused with the use of Workday.Intl as there no days but defer to your better knowledge.

 

[Fluff]

I have put your formula in G3 but am getting SPILL! in return.

Clear all cells from G4 down.

 

[Fluff]

If you just want the results in cols H:J, try

Fluff.xlsm
	A	B	C	D	E	F	G	H	I	J
2
3	Example 1	0.30%		1	21.18%	2		Example 2	21.18%
4	Example 2	21.18%		2	19.35%	21		Example 21	19.35%
5	Example 3	0.30%		3	17.94%	14		Example 14	17.94%
6	Example 4	2.25%		4				Example 1		0.30%
7	Example 5	1.12%		5				Example 3		0.30%
8	Example 6	6.61%		6				Example 4		2.25%
9	Example 7	1.48%		7				Example 5		1.12%
10	Example 8	0.64%		8				Example 6		6.61%
11	Example 9	0.48%		9				Example 7		1.48%
12	Example 10	0.59%		10				Example 8		0.64%
13	Example 11	6.95%		11				Example 9		0.48%
14	Example 12	0.67%		12				Example 10		0.59%
15	Example 13	0.47%		13				Example 11		6.95%
16	Example 14	17.94%		14				Example 12		0.67%
17	Example 15	0.28%		15				Example 13		0.47%
18	Example 16	3.16%		16				Example 15		0.28%
19	Example 17	0.30%		17				Example 16		3.16%
20	Example 18	1.18%		18				Example 17		0.30%
21	Example 19	2.57%		19				Example 18		1.18%
22	Example 20	0.81%		20				Example 19		2.57%
23	Example 21	19.35%		21				Example 20		0.81%
24	Example 22	0.24%		22				Example 22		0.24%
25	Example 23	0.90%		23				Example 23		0.90%
26	Example 24	3.42%		24				Example 24		3.42%
27	Example 25	0.30%		25				Example 25		0.30%
28	Example 26	4.35%		26				Example 26		4.35%
29	Example 27	0.71%		27				Example 27		0.71%
30	Example 28	0.81%		28				Example 28		0.81%
Data

Cell Formulas
Range	Formula
H3:J30	H3	=LET(b,B3:B30,c,F3:F30,f,FILTER(c,c<>""),r,WORKDAY.INTL(0,SEQUENCE(ROWS(b)-ROWS(f)),"0000000",f),rr,VSTACK(f,r),HSTACK(INDEX(A3:A30,rr),IF(c<>"",INDEX(b,rr),""),IF(c="",INDEX(b,rr),"")))
E3:E8	E3	=IF(LARGE($B$3:$B$30,D3)>E$1,LARGE($B$3:$B$30,D3),"")
F3:F5	F3	=IFERROR(SUM(MATCH(E3,$B$3:$B$30,0)),"")
F6:F30	F6	=IFERROR(SUM(MATCH(E6,$B$3:$B$30,0)+2),"")
Dynamic array formulas.

 

[Red over White]

Thanks a lot - that works - way beyond my knowledge!!

Hope you enjoyed the game on Saturday!

 

[Fluff]

You're welcome & thanks for the feedback.

 

[Red over White]

Fluff

I have now successfully transferred your wonderful formula onto the intended sheet. Going back to the sheet that my XL2BB was based on, when I select H3:J30 and then select the doughnut graph from the lower Insert option, the cells in H3:I5 are not selected. Any thoughts?