Let Property passing argument

[tiredofit]

I seem to be confused with regard to ByRef and ByVal.

Here, regardless of ByRef or ByVal, the result in the immediate window is 100. I though ByVal DOESN'T change things.

Option Explicit


    Dim pabc As Long


Sub Test()


    abc = 10
    
    Debug.Print pabc
    
End Sub


Property Let abc(ByVal a)


    a = 100
    
    pabc = a
    
End Property

 

[RoryA]

Property procedures always pass ByVal anyway. I don't really see how that is relevant here though - the a variable is local to the property procedure. The original input was a literal value which is, unsurprisingly, unchanged.

 

[tiredofit]

"Property procedures always passes ByVal"

Then I'm further confused!

Look at this code:

http://www.informit.com/articles/article.aspx?p=1346864

which states:

Option Explicit

Public Enum anlCellType
    anlCellTypeEmpty
    anlCellTypeLabel
    anlCellTypeConstant
    anlCellTypeFormula
End Enum

Private muCellType As anlCellType
Private mrngCell As Excel.Range

Property Set Cell(ByRef rngCell As Excel.Range)
    Set mrngCell = rngCell
End Property

Property Get Cell() As Excel.Range
    Set Cell = mrngCell
End Property

Property Get CellType() As anlCellType
    CellType = muCellType
End Property

Property Get DescriptiveCellType() As String
    Select Case muCellType
        Case anlCellTypeEmpty
            DescriptiveCellType = "Empty"
        Case anlCellTypeFormula
            DescriptiveCellType = "Formula"
        Case anlCellTypeConstant
            DescriptiveCellType = "Constant"
        Case anlCellTypeLabel
            DescriptiveCellType = "Label"
    End Select
End Property

Public Sub Analyze()
    If IsEmpty(mrngCell) Then
        muCellType = anlCellTypeEmpty
    ElseIf mrngCell.HasFormula Then
        muCellType = anlCellTypeFormula
    ElseIf IsNumeric(mrngCell.Formula) Then
        muCellType = anlCellTypeConstant
    Else
        muCellType = anlCellTypeLabel
    End If
End Sub

in particular this line:

Property Set Cell(ByRef rngCell As Excel.Range)
    Set mrngCell = rngCell
End Property

why does he put ByRef if Properties always pass ByVal?

BTW I'm NOT questioning your comment!

 

[RoryA]

I don't know - maybe he forgot. (It doesn't really make any difference there anyway.)

 

[tiredofit]

Thanks.

Can you comment here please - https://www.mrexcel.com/forum/excel-questions/1040126-function-v-get-property.html

 

[mikerickson]

I sometimes will specify a default (such as ByRef in property proceedures) just to remind myself, when I later edit, of what is happening.

Specifying defaults, instead of remembering them, is good practice IMO. No loss of functionality, but saving brain space. E.G. Split("cat dog fish", " ") rather than Split("cat dog fish")

 

[RoryA]

But specifying ByRef has no effect in a property procedure - the argument will be passed ByVal regardless.

 

[tiredofit]

I sometimes will specify a default (such as ByRef in property proceedures) just to remind myself, when I later edit, of what is happening.

Specifying defaults, instead of remembering them, is good practice IMO. No loss of functionality, but saving brain space. E.G. Split("cat dog fish", " ") rather than Split("cat dog fish")

Except that the default with properties is ByVal, NOT ByRef, contrary to the usual rule.

 

[mikerickson]

I put this code in a class module.

Property Get Smith(a As Variant) As String
    a = "cat"
    Smith = "smith"
End Property

And this in a normal module

Sub test()
    Dim x As Variant
    x = "xxx"
    Dim aThing As New Class1
    MsgBox aThing.Smith(x)
    MsgBox x
End Sub

The first message box returned "smith". The second returned "cat".

The default for an argument passed to Property Get is ByRef.

 

[RoryA]

My mistake. I had forgotten that Property Get follows the normal rules (I never use Property Get with arguments hence my rustiness) but Property Let and Set always pass ByVal no matter what you specify.