Last item in row, break to new row

[2Ruff4U]

Hello, and thank you for reviewing:
I have thousands of rows of data with a dollar amount (in text) at the end of the row. I need to "break" the amount to a new row, example follows. Thoughts on how to do this?
Many thanks

Before:
6466861 Name Address Buffalo NY 14206 First Last 85.33
6467271 Name Address Rochester NY 14611 First Last 13.22
6467633 Name Address Akron NY 14001 First Last 506.78

After:
6466861 Name Address Buffalo NY 14206 First Last
85.33
6467271 Name Address Rochester NY 14611 First Last
13.22
6467633 Name Address Akron NY 14001 First Last
506.78

 

[Peter_SSs]

Not sure where you wanted the results. This puts them in column B.

Sub Break_Rows()
  Dim a As Variant, b As Variant, bits As Variant
  Dim i As Long, ub As Long
  
  a = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
  ReDim b(1 To UBound(a) * 2, 1 To 1)
  For i = 1 To UBound(a)
    bits = Split(a(i, 1))
    ub = UBound(bits)
    b(i * 2, 1) = Val(bits(ub))
    bits(ub) = vbNullString
    b(i * 2 - 1, 1) = RTrim(Join(bits))
  Next i
  Range("B2").Resize(UBound(b)).Value = b
End Sub

My sample data & results:

Book1
	A	B
1	Before:
2	6466861 Name Address Buffalo NY 14206 First Last 85.33	6466861 Name Address Buffalo NY 14206 First Last
3	6467271 Name Address Rochester NY 14611 First Last 13.22	85.33
4	6467633 Name Address Akron NY 14001 First Last 506.78	6467271 Name Address Rochester NY 14611 First Last
5		13.22
6		6467633 Name Address Akron NY 14001 First Last
7		506.78
Sheet1

 

[Rick Rothstein]

Assuming the same layout that Peter used in Message #2 , and as long as you have less than 32,769 rows of original data, here is another macro that you can consider...

[table="width: 500"]
[tr]
	[td]Sub MoveLastValueToRowOfItsOwn()
  With Range("A2", Cells(Rows.Count, "A").End(xlUp))
    .Offset(, 1).Resize(2 * .Rows.Count) = Application.Transpose(Split(Join(Application.Transpose(Evaluate(Replace("IF({1},SUBSTITUTE(@,"" "",CHAR(1),LEN(@)-LEN(SUBSTITUTE(@,"" "",""""))))", "@", .Address))), Chr(1)), Chr(1)))
  End With
End Sub[/td]
[/tr]
[/table]