Largest period between two dates

[damian_r_Home]

Morning All.
I have a column tha thas dates in it. These dates are not a text entry, but a value from another cell by a basic formula - see below
=IF(C14="Y",A14,"")

How do you write a formula that can look down this column of dates and then see what the largest period is between any two dates is and show that value in days?
There are many many empty cells in the column.

 

[footoo]

If the formula is in column D : =MAX(D:D)-MIN(D:D)

 

[awoohaw]

I'm not really sure what you want. But try this:
(if this is wrong, then please post your data and expected results. Making the forum guess what your scenario is wastes time and does not help you.
Mr Excel has a tool called xl2bb add in (link below) that allows you post miniworksheets. If you cant use that tool then post your data as a table. As you can see you have two very different suggestions, and both could be wrong. I'm pretty sure i'm wrong because my solution is not a Max of the resulting values.)

Book1
	B	C	D	E	F
14		N
15		N
16		Y		2023-01-10	16
17		N
18		Y		2023-01-25	22
19		N
20		N
21		N
22		Y		2023-02-15	5
23		Y		2023-02-19
Sheet1

Cell Formulas
Range	Formula
E14:E23	E14	=IF(C14="Y",A14,"")
F14:F22	F14	=IF(OR(E14="",AND(ROW(E14)=23,COLUMN(E14)=5)),"",NETWORKDAYS.INTL(E14, INDEX(E15:$E$23,1/MAX(IFERROR(1/(ISNUMBER(E15:$E$23)*(ROW(E15:$E$23)-ROW(E14))),0))),"0000000"))
F23	F23	=IF(OR(E23="",AND(ROW(E23)=23,COLUMN(E23)=5)),"",NETWORKDAYS.INTL(E23, INDEX(E$23:$E24,1/MAX(IFERROR(1/(ISNUMBER(E$23:$E24)*(ROW(E$23:$E24)-ROW(E23))),0))),"0000000"))

 

[Fluff]

Another option

=LET(f,FILTER(E2:E200,E2:E200<>""),MAX(DROP(f,1)-DROP(f,-1)))

 

[damian_r_Home]

Afternoon.
Thanks for your replies, I will try them out later this evening and see what happens.

D