Is this Possible?

[MikeDBMan]

Is it possible to embed an if-then-else statement into a sumproduct function? For example: will this work:

=Sumproduct((table1[Location]=$A$1)*(table1[ProductType]=$A$2)*(if(table1[Period]="Qtr1",1,0))*(table1[extension]))

I have tried it and it just basically "ignores" the period parameters. Any ideas on a work-around. One I thought of is to have different columns in my table for the Q1 amounts, Q2 amounts, etc and then pull from the different Extension columns to get the right stuff. But I was hoping to avoid that extra overhead. Ideas?

 

[Jonmo1]

This should work

=Sumproduct((table1[Location]=$A$1)*(table1[ProductType]=$A$2)*(table1[Period]="Qtr1")*(table1[extension]))

 

[MikeDBMan]

Yes, you are correct. Now I am remembering, the real problem was sometimes I want to include all data regardless of the period and sometimes just one period. In other words, if A3 has "All" in it, then I'd want to pick up all the data. If it has Q1 in it I want to pick up only the Q1 data. Suggestions on how to do that? So my if statement might be:

(if($a$3="All",1,table1[Period]=$a$3)

That does not seem to work.

 

[Aladin Akyurek]

Yes, you are correct. Now I am remembering, the real problem was sometimes I want to include all data regardless of the period and sometimes just one period. In other words, if A3 has "All" in it, then I'd want to pick up all the data. If it has Q1 in it I want to pick up only the Q1 data. Suggestions on how to do that? So my if statement might be:

(if($a$3="All",1,table1[Period]=$a$3)

That does not seem to work.

Try...

=SUMPRODUCT(
    (table1[Location]=$A$1)*
    (table1[ProductType]=$A$2)*
    (table1[Period]=IF(A3="All",table1[Period],A3))*
    (table1[extension]))

Or slightly better:

=SUMPRODUCT(
    --(table1[Location]=$A$1),
    --(table1[ProductType]=$A$2),
    --(table1[Period]=IF(A3="All",table1[Period],A3)),
    (table1[extension]))

 

[MikeDBMan]

Aladin,
your method worked! Thanks so much. I was writing the If-then-else basically backwards. But yours works perfectly!

 

[Aladin Akyurek]

Aladin,
your method worked! Thanks so much. I was writing the If-then-else basically backwards. But yours works perfectly!

Glad to hear that. Thanks for providing feedback.