Is there a way to count values that are of a certain criteria when they are in an array.

[scowie]

Hi,

I have this function, for simplicity's sake it is provided below:

=FREQUENCY(IF(A1:J1<>"", COLUMN(A1:J1)),IF(A1:J1="",COLUMN(A1:J1)))

Cells A1:Z1 are populated with a series of number with blank cells in between them, and the function above calculates how many cells are in a row until a blank cell appears. For example, [TABLE="class: grid, width: 500, align: center"]
<tbody>[TR]
[TD]A[/TD]
[TD]B[/TD]
[TD]C[/TD]
[TD]D[/TD]
[TD]E[/TD]
[TD]F[/TD]
[TD]G[/TD]
[TD]H[/TD]
[TD]I[/TD]
[TD]J[/TD]
[/TR]
[TR]
[TD]10[/TD]
[TD]10[/TD]
[TD][/TD]
[TD][/TD]
[TD]10[/TD]
[TD]10[/TD]
[TD]10[/TD]
[TD][/TD]
[TD][/TD]
[TD]10[/TD]
[/TR]
</tbody>[/TABLE]

So when the function above is Ctrl+Shift+Entered, the output is 2 (three successive cells populated to start), and when I F9 the formula the output is ={2;0;3;0;1}. Is there a way I can implement COUNT in order to count the number of non-zero values in {2;0;3;0;1}, so the output would be 3?

Thank you!!

 

[XOR LX]

Hi.

You could use an array formula**.

Either:

=COUNT(1/FREQUENCY(IF(A1:J1<>"",COLUMN(A1:J1)),IF(A1:J1="",COLUMN(A1:J1))))

or:

=SUM(IF(FREQUENCY(IF(A1:J1<>"",COLUMN(A1:J1)),IF(A1:J1="",COLUMN(A1:J1))),1))

Regards


**Array formulas are not entered in the same way as 'standard' formulas. Instead of pressing just ENTER, you first hold down CTRL and SHIFT, and only then press ENTER. If you've done it correctly, you'll notice Excel puts curly brackets {} around the formula (though do not attempt to manually insert these yourself).

 

[scowie]

Yes that works!! Thanks you very very much!!

 

[XOR LX]

You're welcome!

Cheers