Is there a way to change the format of how the PDF is being printed like landscape? I have 9 columns that I want to print but only getting 4

[APInfa]

I would like to make all 9 columns print on the pdf. Is there a command to switch it to landscape or another horizontal page to fit all the columns on it? Here is the code I am using:

Sub SavetoPDF
MsgBox "Please save changes as PDF: yyyymmdd_hhmm"
Dim wsA As Worksheet
Dim wbA As Workbook
Dim strTime As String
Dim strName As String
Dim strPath As String
Dim strFile As String
Dim strPathFile As String
Dim myFile As Variant

Set wbA = ActiveWorkbook
Set wsA = ActiveSheet
strTime = Format(Now(), "yyyymmdd\_hhmm")

'get active workbook folder, if saved
strPath = wbA.Path
If strPath = "" Then
strPath = Application.DefaultFilePath
End If
strPath = strPath & "\"

'replace spaces and periods in sheet name
strName = Replace(wsA.Name, " ", "")
strName = Replace(strName, ".", "_")

'create default name for savng file
strFile = strName & "_" & strTime & ".pdf"
strPathFile = strPath & strFile

'use can enter name and
' select folder for file
myFile = Application.GetSaveAsFilename _
(InitialFileName:=strPathFile, _
FileFilter:="PDF Files (*.pdf), *.pdf", _
Title:="Select Folder and FileName to save")

'export to PDF if a folder was selected
If myFile <> "False" Then
wsA.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=myFile, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
'confirmation message with file info
MsgBox "PDF file has been created: " _
& vbCrLf _
& myFile
End If
End Sub

 

[John_w]

I would like to make all 9 columns print on the pdf. Is there a command to switch it to landscape

Insert this line just before the wsA.ExportAsFixedFormat _ line:

    wsA.PageSetup.Orientation = xlLandscape

Please use VBA code tags.

 

[APInfa]

Insert this line just before the wsA.ExportAsFixedFormat _ line:

    wsA.PageSetup.Orientation = xlLandscape

Please use VBA code tags.

Awesome Thank you!

 

[APInfa]

Insert this line just before the wsA.ExportAsFixedFormat _ line:

    wsA.PageSetup.Orientation = xlLandscape

Please use VBA code tags.

Is there actually a way to format the text to fit to page? It is still having issues with formatting it all on one page.

 

[John_w]

Try this instead:

        With wsA.PageSetup
            .Orientation = xlLandscape
            .Zoom = False
            .FitToPagesTall = 1
            .FitToPagesWide = 1
        End With

 

[APInfa]

Try this instead:

        With wsA.PageSetup
            .Orientation = xlLandscape
            .Zoom = False
            .FitToPagesTall = 1
            .FitToPagesWide = 1
        End With

Perfect!