Is there a way to apply Conditional Formatting to JUST a number in a text string?

[ajjava]

So, in other words:

I have cells that contain text strings.
The text strings may or may not contain numbers.
In the event that they DO contain numbers, I'd like to set up some way to automatically make JUST THE NUMBERS bold. \

Is this possible? Either via Conditional Formatting or VBA?

Thanks!

 

[Oaktree]

Not with conditional formatting, but you could use a macro for this.

Select the cells and run this:

Sub BoldSelectedNumbers()
Dim my_cell, i
For Each my_cell In Selection
    For i = 1 To Len(my_cell.Value)
        If IsNumeric(Mid(my_cell.Value, i, 1)) Then
            my_cell.Characters(i).Font.Bold = True
        Else
            my_cell.Characters(i).Font.Bold = False
        End If
    Next i
Next my_cell
End Sub

 

[Rick Rothstein]

Not with conditional formatting, but you could use a macro for this.

Select the cells and run this:

Sub BoldSelectedNumbers()
Dim my_cell, i
For Each my_cell In Selection
    For i = 1 To Len(my_cell.Value)
        If IsNumeric(Mid(my_cell.Value, i, 1)) Then
            my_cell.Characters(i).Font.Bold = True
        Else
            my_cell.Characters(i).Font.Bold = False
        End If
    Next i
Next my_cell
End Sub

Not necessarily faster, but I like using the Like operator for this...

If Mid(my_cell.Value, i, 1) Like "#" Then

 

[Momentman]

Maybe using the worksheet change event

The example below tracks changes to ant cell from A1 to A10 on the Sheet

Right click the Sheet Tab, Select "View code" and paste the code below in there

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim I As Long
    If Not Intersect(Target, Range("A1:A10")) Is Nothing Then
        For I = 1 To Len(Target)
            If IsNumeric(Mid(Target.Value, I, 1)) Then
                Target.Characters(I, 1).Font.Bold = True
            Else
                Target.Characters(I, 1).Font.Bold = False
            End If
        Next I
    End If
End Sub

Didn't See the other posts when i posted(I guess I had not refreshed the page)---well, I will just keep my solution here

 

[ajjava]

Thanks, all! Worked just like I needed it to.

 

[Oaktree]

Not necessarily faster, but I like using the Like operator for this...

If Mid(my_cell.Value, i, 1) Like "#" Then

Interesting. I found your write-up here http://www.excelfox.com/forum/showt...sing-VBA-s-IsNumeric-Function-Read-this-first about the problems currency symbols, parentheses, commas, and perhaps others can cause with IsNumeric. Good to know!