Is there a better replacement for this formula?

[AWM21]

Hello, I'm betting there is a better way to run this formula that references a block of dates by month, and returns the table rows based on the short date related to the selected month. In the example below, I have a dynamic array showcasing the rows of data from a table based on the month selected in the Orange data list. The data list looks at the month selected and references it to the starting date of that month. I then used EOMONTH to cross reference the table for anything less than, or equal to, the the associated month selected short date.

Here is the formula as it sits:
=FILTER(TROY,(TROY[Load Out Date]>=XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13))*(TROY[Load Out Date]<=EOMONTH(XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),0)),"Currently No Events Scheduled")

The section of this formula that I believe can be simplified is:
(TROY[Load Out Date]>=XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13))*(TROY[Load Out Date]<=EOMONTH(XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),0))

Is there a better way to extract the data by month instead of using this series of XLOOKUP references?
The "Month" & "Start" columns in the upper left only exist in order to work the XLOOKUP formula references. This can go away if that helps get a better solution.

Thanks!

Sample Data v1a.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Month	Start
2	January	1/1/2022			April										$ 61,423.61
3	February	2/1/2022			Name	Number	Parent Name	Account Manager	Client	Company	Status	Prep Date	Load Out Date	Return Date	Total
4	March	3/1/2022			Name_br	P01-0065	Parent_br	Rep_02	Client_y	Company_y	Confirmed	4/1/2022	4/4/2022	4/5/2022	$ 3,039.00
5	April	4/1/2022			Name_o	P01-0169	Parent_o	Rep_03	Client_j	Company_j	Tentative	4/1/2022	4/5/2022	4/7/2022	$ 1,119.36
6	May	5/1/2022			Name_bf	P01-0103	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 5,990.00
7	June	6/1/2022			Name_bf	P01-0111	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 7,460.00
8	July	7/1/2022			Name_bf	P01-0107	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 8,900.00
9	August	8/1/2022			Name_bf	P01-0086	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 34,915.25
10	September	9/1/2022
11	October	10/1/2022
12	November	11/1/2022
13	December	12/1/2022
14
15
16
17					Name	Number	Parent Name	Account Manager	Client	Company	Status	Prep Date	Load Out Date	Return Date	Total
18					Name_aa	P01-0046	Parent_aa	Rep_06	Client_o	Company_o	Invoice Created	1/1/2022	1/3/2022	1/3/2022	$ 2,700.00
19					Name_az	P01-0026	Parent_az	Rep_07	Client_a	Company_a	Invoice Created	1/8/2022	1/11/2022	1/12/2022	$ 33,200.00
20					Name_q	P01-0012	Parent_q	Rep_02	Client_q	Company_q	Invoice Created	1/6/2022	1/12/2022	1/17/2022	$ 5,390.75
21					Name_q	P01-0011	Parent_q	Rep_02	Client_q	Company_q	Invoice Created	1/6/2022	1/12/2022	1/17/2022	$ 51,987.80
22					Name_q	P01-0009	Parent_q	Rep_02	Client_q	Company_q	Invoice Created	1/6/2022	1/12/2022	1/17/2022	$ 180,827.93
23					Name_ad	P01-0048	Parent_ad	Rep_02	Client_i	Company_i	Invoice Created	1/28/2022	2/1/2022	2/2/2022	$ 11,260.00
24					Name_ak	P01-0014	Parent_ak	Rep_02	Client_e	Company_e	Invoice Created	1/27/2022	2/5/2022	2/8/2022	$ 59,953.90
25					Name_bn	P01-0106	Parent_bn	Rep_05	Client_x	Company_x	Invoice Created	2/11/2022	2/11/2022	2/11/2022	$ 800.00
26					Name_bi	P01-0066	Parent_bi	Rep_05	Client_g	Company_g	Invoice Created	2/7/2022	2/16/2022	2/17/2022	$ 24,515.00
27					Name_bk	P01-0069	Parent_bk	Rep_05	Client_x	Company_x	Invoice Created	2/11/2022	2/16/2022	2/17/2022	$ 29,603.75
28					Name_ac	P01-0067	Parent_ac	Rep_02	Client_i	Company_i	Invoice Created	2/2/2022	2/17/2022	2/17/2022	$ 11,260.00
29					Name_be	P01-0070	Parent_be	Rep_05	Client_x	Company_x	Invoice Created	2/11/2022	2/17/2022	2/17/2022	$ 16,723.00
30					Name_u	P01-0153	Parent_u	Rep_04	Client_v	Company_v	Confirmed	3/11/2022	3/14/2022	3/15/2022	$ 2,936.00
31					Name_s	P01-0181	Parent_s	Rep_07	Client_a	Company_a	Invoice Created	3/15/2022	3/16/2022	3/16/2022	$ 2,478.50
32					Name_bh	P01-0120	Parent_bh	Rep_05	Client_x	Company_x	Confirmed	3/11/2022	3/16/2022	3/17/2022	$ 50,458.75
33					Name_bh	P01-0184	Parent_bh	Rep_05	Client_x	Company_x	Confirmed	3/11/2022	3/16/2022	3/17/2022	$ 367.50
34					Name_bh	P01-0187	Parent_bh	Rep_05	Client_x	Company_x	Confirmed	3/11/2022	3/16/2022	3/17/2022	$ -
35					Name_ar	P01-0098	Parent_ar	Rep_05	Client_u	Company_u	Confirmed	2/4/2022	3/31/2022	4/1/2022	$ 11,838.00
36					Name_br	P01-0065	Parent_br	Rep_02	Client_y	Company_y	Confirmed	4/1/2022	4/4/2022	4/5/2022	$ 3,039.00
37					Name_o	P01-0169	Parent_o	Rep_03	Client_j	Company_j	Tentative	4/1/2022	4/5/2022	4/7/2022	$ 1,119.36
38					Name_bf	P01-0103	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 5,990.00
39					Name_bf	P01-0111	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 7,460.00
40					Name_bf	P01-0107	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 8,900.00
41					Name_bf	P01-0086	Parent_bf	Rep_05	Client_x	Company_x	Confirmed	2/7/2022	4/8/2022	4/6/2022	$ 34,915.25
42					Name_ba	P01-0104	Parent_ba	Rep_02	Client_y	Company_y	Tentative	5/11/2022	5/12/2022	5/13/2022	$ 12,675.50
43					Name_aj	P01-0177	Parent_aj	Rep_05	Client_x	Company_x	Tentative	5/13/2022	5/18/2022	5/19/2022	$ 48,718.75
44					Name_au	P01-0061	Parent_au	Rep_05	Client_ab	Company_ab	Confirmed	5/12/2022	5/18/2022	5/23/2022	$ 52,250.25
45					Name_bl	P01-0202	Parent_bl	Rep_05	Client_x	Company_x	Inquiry	5/17/2022	5/20/2022	5/23/2022	$ -
46					Name_au	P01-0175	Parent_au	Rep_05	Client_ab	Company_ab	Confirmed	5/12/2022	5/23/2022	5/23/2022	$ 3,900.00
47					Name_i	P01-0209	Parent_i	Rep_04	Client_s	Company_s	Inquiry	5/20/2022	5/26/2022	5/27/2022	$ 35,133.50
48					Name_ag	P01-0186	Parent_ag	Rep_02	Client_y	Company_y	Confirmed	5/20/2022	5/26/2022	5/30/2022	$ 12,493.00
49					Name_ah	P01-0150	Parent_ah	Rep_02	Client_y	Company_y	Inquiry	5/20/2022	5/26/2022	5/30/2022	$ 92,953.75
50					Name_r	P01-0033	Parent_r	Rep_02	Client_q	Company_q	Confirmed	6/9/2022	6/15/2022	6/17/2022	$ 6,564.50
51					Name_r	P01-0032	Parent_r	Rep_02	Client_q	Company_q	Confirmed	6/9/2022	6/15/2022	6/17/2022	$ 29,042.40
52					Name_r	P01-0029	Parent_r	Rep_02	Client_q	Company_q	Confirmed	6/9/2022	6/15/2022	6/17/2022	$ 189,669.75
53					Name_ai	P01-0031	Parent_ai	Rep_02	Client_q	Company_q	Tentative	9/14/2022	9/23/2022	9/27/2022	$ 1,950.00
54					Name_ai	P01-0136	Parent_ai	Rep_02	Client_q	Company_q	Inquiry	9/14/2022	9/23/2022	9/27/2022	$ 10,440.50
55					Name_ai	P01-0140	Parent_ai	Rep_02	Client_q	Company_q	Inquiry	9/14/2022	9/23/2022	9/27/2022	$ 10,440.50
56					Name_ai	P01-0137	Parent_ai	Rep_02	Client_q	Company_q	Inquiry	9/14/2022	9/23/2022	9/27/2022	$ 10,440.50
57					Name_ai	P01-0141	Parent_ai	Rep_02	Client_q	Company_q	Inquiry	9/14/2022	9/23/2022	9/27/2022	$ 10,440.50
58					Name_ai	P01-0143	Parent_ai	Rep_02	Client_q	Company_q	Inquiry	9/14/2022	9/23/2022	9/27/2022	$ 10,440.50
59					Name_an	P01-0190	Parent_an	Rep_05	Client_m	Company_m	Inquiry	8/1/2022	11/14/2022	11/14/2022	$ 113,300.00
60					Name_an	P01-0192	Parent_an	Rep_05	Client_m	Company_m	Inquiry	8/1/2022	11/14/2022	11/14/2022	$ 115,850.00
61					Name_an	P01-0189	Parent_an	Rep_05	Client_m	Company_m	Inquiry	8/1/2022	11/14/2022	11/14/2022	$ 116,700.00
62					Name_an	P01-0191	Parent_an	Rep_05	Client_m	Company_m	Inquiry	8/1/2022	11/14/2022	11/14/2022	$ 119,100.00
63					Name_ap	P01-0089	Parent_ap	Rep_04	Client_l	Company_l	Inquiry	11/14/2022	12/26/2022	12/30/2022	$ 56,956.00
64					Name_ap	P01-0088	Parent_ap	Rep_04	Client_l	Company_l	Inquiry	11/14/2022	12/26/2022	12/30/2022	$ 114,369.00
Quotes_P01

Cell Formulas
Range	Formula
O2	O2	=SUMIFS(TROY[Total],TROY[Load Out Date],">="&XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),TROY[Load Out Date],"<="&EOMONTH(XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),0))
E4:O9	E4	=FILTER(TROY,(TROY[Load Out Date]>=XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13))*(TROY[Load Out Date]<=EOMONTH(XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),0)),"Currently No Events Scheduled")
Dynamic array formulas.

Cells with Data Validation
Cell	Allow	Criteria
E2	List	=$A$2:$A$13

 

[Peter_SSs]

You can streamline your existing approach ..

=FILTER(TROY,(TROY[Load Out Date]>=XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13))*(TROY[Load Out Date]<=EOMONTH(XLOOKUP($E$2,$A$2:$A$13,$B$2:$B$13),0)),"Currently No Events Scheduled")

.. a little by employing the LET function & ditching the absolute references.

=LET(XL,XLOOKUP(E2,A2:A13,B2:B13),LOD,TROY[Load Out Date],FILTER(TROY,(LOD>=XL)*(LOD<=EOMONTH(XL,0)),"Currently No Events Scheduled"))

If all your dates are in the same year then you could use this

=FILTER(TROY,TEXT(TROY[Load Out Date],"mmmm")=E2,"Currently No Events Scheduled")

If dates span multiple years than a modification would be needed. Post back with more details/sample if this is the case and you want more help.

 

[AWM21]

Thanks Peter! I see what you mean about the year. If this document lives that long, I'll worry about it then. I told my colleague that, for what he is asking for in the overall document, he is getting into Sales Force or Power BI territory.
I didnt think to use LET like that.
Thanks again Peter, I really appreciate the help here. Have a great rest of your weekend!

 

[Peter_SSs]

You're welcome. Hope it all works out for you.