Is it possible to reuse an opened shell command from Excel VBA

[cmosate]

I am using a shell command to communicate with a device under test and would like to open this shell once, change directory to a specific one and then send different text strings to it at various times during my test program. The code below works perfectly fine but opens and closed the shell each time it is used. I think it woud be quicker if I could reuse it until done and then exit out of it.

Here are 2 examples of a couple different strings I would like to pass into the cmdShell function at various times. I would like to send the first string, perform some measurements and then repeat with the 2nd string.

i.e. shellStr1 = ("cd \.. & cd c:\ezspi & testdm900 --widn 0x1020 --widv 0x1") then once the shell is open and the directory has been set send shellStr = ("testdm900 --widn 0x1020 --widv 0x5")

Is this possible using WShell Script or do I need another method?

Public Sub cmdShell(shellStr As String)
Dim Test As Double
Dim response As VbMsgBoxResult
Dim cmdObject As Object
Dim ReferenceTime As Double, ElapsedTime As Double

Set objShell = CreateObject("WScript.Shell")

Test = Shell("cmd /c " & shellStr, vbHide)
' Test = Shell("cmd /k " & shellStrvbNormalFocus)

End Sub

 

[andrewkard]

Hello, i think you cannot use the same window cmd but you can use more commands in it, for example:

Call Shell("cmd.exe /k cd /d d:\ & chdir d:\1 & cd /d c:\", 1)

 

[cmosate]

Thanks for the response!

I agree, I have sent multiple commands in the same string but not in different strings and/or at different times. I think another method like Power Shell or something else is required.

 

[andrewkard]

I am not sure, but maybe you should try find the cmd window and try to place commands in it. Try to search in google:
"Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long". Maybe this helps...

 

[John_w]

Try this:

Option Explicit

Private Const ConsoleWindowClassName As String = "ConsoleWindowClass"
Private Const WM_CHAR As Long = &H102

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
    (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" _
    (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long


Sub Test()
    'Optional - open new command window
    Shell "cmd /k", vbNormalFocus
    Application.Wait DateAdd("s", 1, Now)
    
    Send_Command "dir" & vbCrLf
End Sub


Public Sub Send_Command(command As String)

    'Send command to an existing command window
    
    Dim hWnd As Long
    Dim i As Integer
    
    hWnd = FindWindow(ConsoleWindowClassName, "Command Prompt")
    If hWnd = 0 Then hWnd = FindWindow(ConsoleWindowClassName, "C:\Windows\system32\cmd.exe")
    If hWnd <> 0 Then
        For i = 1 To Len(command)
            PostMessage hWnd, WM_CHAR, Asc(Mid(command, i, 1)), 0&
        Next
    Else
        MsgBox "Command window not found"
    End If
        
End Sub