Invalid qualifier

[dpaton05]

I have a procedure that moves some buttons. They need to be moved to just below the bottom of the last entry in column A.
I get an error saying invalid qualifier and the lRow on the 9th line is highlighted.

I had this code:

Sub Move_Shape()
    Dim Total As Range, ws As Worksheet, Sh As Shape, NewShape As Shape, x As Long
    Dim TTop As Long, TLeft As Long, txtMainExists As Boolean, lRow As Long
    Set ws = ThisWorkbook.Worksheets("ACA_Quoting")
    
    'Find last row in column A after rows have been copied and add 1 row
    lRow = Cells(Rows.Count, "A").End(xlUp).Row + 1
    'Set the position of  the top of 1 row below the last row in column A
    x = lRow.top

    
    For Each Sh In ws.Shapes
        Debug.Print Sh.Type
        Select Case Sh.Name
        Case "cmdAddRatio", "cmdCustomSign", "cmdGsign", "cmdAsign", "cmdNoSign", "cmdSaveToPdf"
            Sh.IncrementTop x
        Case "txtMain"                                'name your first textbox, the one you want to move,  to something unique. I used "txtMain"
            txtMainExists = True
            TTop = Sh.Top                             'record position
            TLeft = Sh.Left
            Sh.IncrementTop x
            Sh.Copy                                   'make a copy
            ws.Paste
            Set NewShape = ws.Shapes(ws.Shapes.Count)    'pasted textbox is the last shape
            With NewShape
                .Top = TTop                           'move the copy to the previous position of txtMain
                .Left = TLeft
                .OLEFormat.Object.Object.Text = .Name & "    (a copy of txtMain)"
            End With
        End Select
    Next Sh
    If Not txtMainExists Then
        MsgBox "txtMain is missing!", vbCritical
    End If
End Sub

Could someone help me please?

 

[DanteAmor]

Change this
x = lRow.top

For this
x = Range("A" & lRow).Top

 

[dpaton05]

Thanks for that Dante, now I just got to work out why it has moved the buttons about 31 rows too far.

 

[Michael M]

Are you sure lrow needs to be based on Col "A" ?
Is lrow returning the correct / required row number ?

 

[DanteAmor]

Thanks for that Dante, now I just got to work out why it has moved the buttons about 31 rows too far.

Check if after the "last" row with data in column A, you have any cell below with blank spaces

 

[dpaton05]

Check if after the "last" row with data in column A, you have any cell below with blank spaces

There is nothing, I even deleted a heap of rows below to make sure.

 

[Michael M]

Did you read post #4 ?
You haven't got any page breaks in there have you ??

 

[dpaton05]

Are you sure lrow needs to be based on Col "A" ?
Is lrow returning the correct / required row number ?

lrow returns the correct row number and there is not any page breaks.

I am not sure if this is the best way to do this or not but I don't know of any other way.

 

[dpaton05]

What needs to happen is when the procedure is run, the shapes need to be moved to just below the last entry in column A.

 

[DanteAmor]

Change to this:

        Case "cmdAddRatio", "cmdCustomSign", "cmdGsign", "cmdAsign", "cmdNoSign", "cmdSaveToPdf"
            Sh.Top = x
        Case "txtMain"                                'name your first textbox, the one you want to move,  to something unique. I used "txtMain"
            txtMainExists = True
            TTop = Sh.Top                             'record position
            TLeft = Sh.Left
            Sh.Top =  x