Invalid formula?

[Stevekgreer]

I am running Excel 2003. This formula keeps coming up "invalid" and I am unable to find my mistake. ANY help is greatly appreciated!!

=IF(AND(ISBLANK(E15),ISBLANK(E17),ISBLANK(E18)),"",IF(AND(ISNUMBER(E15),ISNUMBER(E17),ISNUMBER(E18)),E15+E17+E18,
IF(AND(ISNUMBER(E15),ISNUMBER(E17),ISBLANK(E18)),E15+E17,IF(AND(ISNUMBER(E15),ISBLANK(E17),ISNUMBER(E18)),E15+E18,
IF(AND(ISBLANK(E15),ISBLANK(E17),ISNUMBER(E18)),E18,IF(AND(ISBLANK(E15),ISNUMBER(E17),ISNUMBER(E18)),E17+E18,
IF(AND(ISBLANK(E15),ISNUMBER(E17),ISBLANK(E18)),E17,"")))))))

I have run the "Insert - Function" check, and all my checks come up ok - no red invalid flags. I've checked my tautology and I think I've covered all the bases. I have 3 cells that I have to check. Each cell can either be blank or contain a value. I need to isolate the cell(s) with the value(s) and add them together for the result, or, if only one cell has a value, post that value, or if none have values, leave the target empty.

I know it's a lot of nested if's, so feel free to give this on a pass, or copy & past and go for the ring.
Thanks in advance for any and all help

 

[Michael M]

This worked for me.....but you have exceeded the IF limit for 2003, which is 7 IF's in a formula

=IF(AND(E15="",E17="",E18=""),"",IF(AND(E15<>"",E17<>"",E18<>""),E15+E17+E18,IF(AND(E15<>"",E17<>"",E18=""),E15+E17,IF(AND(E15<>"",E17="",E18<>""),E15+E18,IF(AND(E15<>"",E17<>"",E18=""),E15+E17,IF(AND(E15<>"",E17="",E18<>""),E15+E18,IF(AND(E15="",E17="",E18<>""),E18,IF(AND(E15="",E17<>"",E18<>""),E17+E18,IF(AND(E15="",E17<>"",E18=""),E17,"")))))))))

but what are you trying to do ....does text get used in any of the cells.

This also did the same for me...

=IF(AND(E15="",E17="",E18=""),"",E15+E17+E18)

 

[Michael M]

If there is a chance of text getting entered, You could also use....

=IF(AND(E15="",E17="",E18=""),"",IF(OR(ISTEXT(E15),ISTEXT(E17),ISTEXT(E18)),"no text allowed",E15+E17+E18))

 

[sandy666]

or

=IF(SUM(E15,E17:E18)=0,"",SUM(E15,E17:E18))

 

[Stevekgreer]

If there is a chance of text getting entered, You could also use....

=IF(AND(E15="",E17="",E18=""),"",IF(OR(ISTEXT(E15),ISTEXT(E17),ISTEXT(E18)),"no text allowed",E15+E17+E18))

Tremendous appreciation to all. Especially those who know the limitations with 2003! I have reworked the formula and resolved my dilemma.
Thanks again for your valuable time.

 

[Stevekgreer]

Tremendous appreciation to all. Especially those who know the limitations with 2003! I have reworked the formula and resolved my dilemma.
Thanks again for your valuable time.

 

[Michael M]

Glad we could help