Inserting an image from the browse dialog box using vba

[dpaton05]

I have made a spreadsheet for my supervisor and he wants the ability to insert a custom signature file at the bottom of a sheet using the browse dialogue box. I already have two buttons that enter a signature each. The signatures are in the right position.

Sub cmdJakeSig()
    ActiveSheet.Unprotect Password:="npssadmin"
        Dim sht As Worksheet
        Set sht = ActiveSheet
        Dim lr As Long
        'Find the last used row in Column A of target.  Change column as required
            lr = Sheets("NPSS_quote_sheet").Range("A" & Rows.Count).End(xlUp).Row + 4
            Sheets("sheet2").Shapes("ImgJ").Copy
            Sheets("NPSS_quote_sheet").Paste _
            Destination:=Worksheets("NPSS_quote_sheet").Range("A" & lr + 6)
    
    'ActiveSheet.Protect Password:="npssadmin"
End Sub

The code copies a set image from another sheet to the right spot. I want to be able to browse for an image and enter it in the same position on NPSS_quote_sheet without needing to enter it into sheet 2 and the copy it from sheet2. Could someone help me with the vba code please?

 

[Michael M]

Maybe something like this

Sub ChangeImage()
ActiveSheet.Unprotect Password:="npssadmin"
Dim lr As Long
lr = Sheets("NPSS_quote_sheet").Range("A" & Rows.Count).End(xlUp).Row + 4
 With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = False
        .ButtonName = "Submit"
        .Title = "Select an image file"
        .Filters.Clear
        .Filters.Add "JPG", "*.JPG"
        
        If .Show = -1 Then
            Dim img As Object
            Set img = ActiveSheet.Pictures.Insert(.SelectedItems(1))
            'Position Image
            img.Left = 0
            img.Top = ActiveSheet.Range("A" & lr + 6).Top
            img.Width = 150
            img.Height = 150
        Else
            MsgBox ("Cancelled.")
        End If
    End With
End Sub

 

[dpaton05]

Thanks for that Michael, worked perfectly.