insert rows after change in range of numbers

[jelly77]

hi,
i have a spreadsheet that contains lots of data and i need to add rows at various points based on cell value in column t, the problem i have is that the column contains continuous data such as below but a lot more
161000
161001
161009
170000
171253
183653
250000
260125
262545
the ranges are the first 2 digits ie. 16, 17, 18, 25 & 26. what i require is for a row to be added after each range. is this possible and if so how would i go about it

many thanks

 

[Joe4]

Try this VBA code:

Sub MyInsertRows()

    Dim lRow As Long
    Dim r As Long
    
    Application.ScreenUpdating = False
    
'   Find last row with data in column T
    lRow = Cells(Rows.Count, "T").End(xlUp).Row
    
'   Loop through all last row to top
    For r = lRow To 2 Step -1
'       Check to see if prefix matches row above it
        If Left(Cells(r, "T"), 2) <> Left(Cells(r - 1, "T"), 2) Then
            Rows(r).Insert
        End If
    Next r
    
    Application.ScreenUpdating = True
        
End Sub

 

[jelly77]

Joe4
so quick that is amazing thank you very much. just what i needed

 

[Joe4]

You are welcome. Glad I could help.