Insert/Replace with Sequential Number as a letter/symbol occur down on a column

[seeke]

In column A, I have a symbol "#" occur in random rows; a "#" in one whole cell; i.e. an "#" in A2, A4, or A35, throughout to A4390.
I want to insert a sequential number next to the "#" as it occurs down the column.
So the first "#" would be replaced as "#1"; then the second "#" would be "#2"; the 3rd "#" would be "#3"; then the 134th "#" would be "#134";

Thank you so much. By the way, this is my first time here, and I'm pretty new to excel. I've spent sometime searching for the solution, but without knowledge of macro/codes, I'm not even sure whether I have already found the solution (or similar to the solution), so I decided to post question specifically regarding my situation.

-seeke

 

[Michael M]

Hi Seeke and welcome to the Board
try this

Sub seq()
Dim lr As Long, r As Long, c As Integer
lr = Cells(Rows.Count, "A").End(xlUp).Row
c = 1
    For r = 1 To lr
        If Range("A" & r).Value = "#" Then
            Range("A" & r).Value = "#" & c
            c = c + 1
        End If
    Next r
End Sub

 

[JoeMo]

Since you have several thousand rows, this might run a bit faster than Michael's code:

Sub PoundSignAddendum()
Const sFnd As String = "#"
Dim lR As Long, R As Range, F As Range, i As Long, fAdr As String
lR = Range("A" & Rows.Count).End(xlUp).Row
Set R = Range("A1", "A" & lR)
With R
    Set F = .Find(what:=sFnd, after:=[A1], LookIn:=xlValues, _
        lookat:=xlWhole, searchorder:=xlByRows, _
        searchdirection:=xlNext)
    If F Is Nothing Then Exit Sub
    fAdr = F.Address
    i = 1
    Do
        F.Value = F.Value & i
        i = i + 1
        Set F = .FindNext(F)
        If F Is Nothing Then Exit Sub
    Loop While F.Address <> fAdr
 End With
End Sub

 

[Michael M]

Yeah, good choice Joe ....

 

[seeke]

Thanks Joe! It works.
Michael's works too, until it was bugged out shortly by a cell with "#NAME?" (which I'd need to fix) instead of "#" alone.

Nevertheless, thanks so much Michael and Joe; that was quick.

-seeke