Insert picture

[fireslguk]

How do I enable a button shape to click and insert picture just to load dialog as sometimes different pictures will be selected

 

[Domenic]

Try assigning the following macro to your button shape...

Option Explicit

Sub Insert_Picture()

    'prompt user to select picture
    Dim pictureFilename As Variant
    pictureFilename = Application.GetOpenFilename( _
        FileFilter:="Image Files (*.gif;*.jpg;*.png), *.gif;*.jpg;*.png", _
        Title:="Insert Picture", _
        ButtonText:="Insert")
       
    'if user cancels, exit sub
    If pictureFilename = False Then Exit Sub
   
    'insert and position picture at active cell
    ActiveSheet.Shapes.AddPicture _
        Filename:=pictureFilename, _
        linktofile:=msoFalse, _
        savewithdocument:=msoTrue, _
        Left:=ActiveCell.Left, _
        Top:=ActiveCell.Top, _
        Width:=-1, _
        Height:=-1
   
End Sub

You can add and/or change the image file types as desired.

Hope this helps!

 

[fireslguk]

Fantastic ! Thankyou - I note within the code a width and height script, what does this function do ? As I would like to set a specific size of the picture

 

[Domenic]

With -1 as their value, the width and height default to their original picture size. Simply replace -1 with the desired width and height.

 

[fireslguk]

Thanks Domenic, Happy new year ??

 

[Domenic]

You're very welcome, and Happy New Year to you too!

Cheers!