Insert IFERROR( and ,"-") at the begining and end of formulas?

[excelos]

How can I insert IFERROR( and ,"-") at the begining and end of formulas?

With search/replace?

Thanks!

 

[mole999]

Re: How can I insert IFERROR( and ,"-") at the begining and end of formulas?

something like ASAP utilities, if when you do it, you also add ' (i.e. =becomes '=IFERROR( as the first character then it will look like text until you have finished changing, then remove the leading '

 

[MARK858]

Re: How can I insert IFERROR( and ,"-") at the begining and end of formulas?

If none of your cells already have an IFERROR formula you can test the below amended Chris Newman code.
Just select the cells and run the macro.

Sub WrapIfError()

'PURPOSE: Add an IFERROR() Function around all the selected cells' formulas
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range
Dim cell As Range
Dim x As String

'Determine if a single cell or range is selected
  If Selection.Cells.Count = 1 Then
    Set rng = Selection
    If Not rng.HasFormula Then GoTo NoFormulas
  Else
    'Get Range of Cells that Only Contain Formulas
      On Error GoTo NoFormulas
        Set rng = Selection.SpecialCells(xlCellTypeFormulas)
      On Error GoTo 0
  End If

'Loop Through Each Cell in Range and add =IFERROR([formula],"-")
  For Each cell In rng.Cells
    x = cell.Formula
    cell = "=IFERROR(" & Right(x, Len(x) - 1) & "," & Chr(34) & "-" & Chr(34) & ")"
  Next cell

Exit Sub

'Error Handler
NoFormulas:
  MsgBox "There were no formulas found in your selection!"

End Sub

 

[excelos]

Thanks but can you give me the exact pairs for search/replace?

Thanks

 

[mole999]

Thanks but can you give me the exact pairs for search/replace?

Thanks

If you select your formulas and run Marks code then you don't need to do anything else