Insert Copied Cells every time a value shows

[KiloHotel]

Hi guys,

Is there a VBA code that someone can help me with, What I am trying to achieve is insert a row of copied cells to another row that has a value of "here"

A4 is the row I want to copy.

So along Column B each cell has the formula ;

=IF(C5=C4,"","HERE")

And the value returns as HERE at random rows and it is quite a lengthy process to copy and paste 1000's of rows of data, I am certain there is a VBA wizard on here that has a simple solution.

And of course if anything else needs clarifying, Just ask away.

Thanks in advance!

 

[HaHoBe]

Hi KiloHotel,

please test the codes on copies of your original data and see if it comes near to what you want to do, both codes will work on the ActiveSheet in Excel:

Sub MrE1612515_ValuesRow4()
'https://www.mrexcel.com/board/threads/insert-copied-cells-every-time-a-value-shows.1219751/
Dim lngMax As Long
Dim lngcounter As Long

With ActiveSheet
  lngMax = WorksheetFunction.Max(.Range("B" & .Rows.Count).End(xlUp).Row, .Range("C" & .Rows.Count).End(xlUp).Row)
  For lngcounter = 5 To lngMax
    If UCase(.Cells(lngcounter, "B").Value) = "HERE" Then
      .Rows(lngcounter).Value = .Rows(4).Value
    End If
  Next lngcounter
End With
End Sub

Sub MrE1612515_FormulasRow4()
'https://www.mrexcel.com/board/threads/insert-copied-cells-every-time-a-value-shows.1219751/
Dim lngMax As Long
Dim lngcounter As Long
Dim lngCalc As Long

lngCalc = Application.Calculation
Application.Calculation = xlCalculationManual
With ActiveSheet
  lngMax = WorksheetFunction.Max(.Range("B" & .Rows.Count).End(xlUp).Row, .Range("C" & .Rows.Count).End(xlUp).Row)
  For lngcounter = 5 To lngMax
    If UCase(.Cells(lngcounter, "B").Value) = "HERE" Then
      .Rows(4).Copy .Rows(lngcounter)
    End If
  Next lngcounter
End With
Application.Calculation = lngCalc
End Sub

Ciao,
Holger